need help show all data in listbox on userform

[Alaa mg]

hi
can any body convert show all columns insted of on column ,please? my data start from COL A: E so based on condition it just show one column A . i would show all of the columns in listbox when run the userform .

Private Sub UserForm_Initialize()
Dim a, b, i As Long, x, y
With Sheets("sheet1")
    a = .Range("E1", .Range("E65536").End(xlUp)).Value
    b = .Range("A1", .Range("b65536").End(xlUp)).Value


End With

With Me.ListBox1

    For i = LBound(a) To UBound(a)
        If IsDate(a(i, 1)) Then
            x = DateSerial(Year(Date), Month(a(i, 1)), Day(a(i, 1)))
            'y = DateDiff("d", x, Date)
            If x >= Date Then
                .AddItem b(i, 1)
               
            End If
        End If
    Next
End With
End Sub

 

[Domenic]

Try the following...

Private Sub UserForm_Initialize()

    Dim data As Variant
    With Sheets("sheet1")
        data = .Range("A1:E" & .Cells(.Rows.Count, "A").End(xlUp).Row)
    End With
    
    Dim dt As Date
    Dim i As Long
    Dim j As Long
    With Me.ListBox1
        For i = LBound(data) To UBound(data)
            If IsDate(data(i, 5)) Then
                dt = data(i, 5)
                dt = DateSerial(Year(Date), Month(dt), Day(dt))
                If dt >= Date Then
                    .AddItem data(i, 1)
                    For j = 2 To .ColumnCount
                        .List(.ListCount - 1, j - 1) = data(i, j)
                    Next j
                End If
            End If
        Next
    End With
    
End Sub

Hope this helps!

 

[Alaa mg]

excellent ! thanks so much for your updating

 

[Domenic]

You're very welcome, glad I could help, cheers!