Need VBA code to delete entire row if cells in Column C are highlighted red

[PaigeWarner]

I already have conditional formatting in my macro to highlight cells red that meet certain conditions I've assigned but I need VBA coding to add that tells the sheet to delete any row that is highlighted red in column c.

 

[jolivanes]

Sub Maybe_A()
Dim i As Long, j As Long, strArr
Application.ScreenUpdating = False
strArr = Array("info", "quote", "hola", "too much")    '<----- Put all the strings in here between double quotation marks
    For i = Cells(Rows.Count, 3).End(xlUp).Row To 2 Step -1
        For j = LBound(strArr) To UBound(strArr)
            If InStr(Cells(i, 3), strArr(j)) <> 0 Then Cells(i, 3).EntireRow.Delete: Exit For
        Next j
    Next i
Application.ScreenUpdating = True
End Sub

 

[PaigeWarner]

It is the standard conditional formatting Light Red Fill with Dark Red Text. The fill RGB is 255,199,206.

 

[MARK858]

Light red isn't the standard red try...

Sub DeleteRed()
    Dim lr As Long, i As Long
    Application.ScreenUpdating = False
    
    lr = Range("C" & Rows.Count).End(xlUp).Row
    
    For i = lr To 2 Step -1
        
        If Cells(i, "C").DisplayFormat.Interior.Color = RGB(255, 199, 206) Then Rows(i).Delete
 
    Next
    
    Application.ScreenUpdating = True
End Sub

 

[PaigeWarner]

That worked, thank you so much for your help!

 

[jolivanes]

I stand corrected
Started in Excel 2010 so my 2007 leaves me in the dark!

 

[Larry Haydn]

You can filter the cells by color, then delete the visible rows.

 

[MARK858]

That worked, thank you so much for your help!

You're welcome, happy we could help.

You can filter the cells by color, then delete the visible rows.

Thanks for that, always forget that Filter by Color does include Conditional formatting.

Sub Filterit2()
    Application.ScreenUpdating = False
 
    With Range("C1:C" & Range("C" & Rows.Count).End(xlUp).Row)
 
        .AutoFilter 1, RGB(255, 199, 206), xlFilterCellColor
      
        On Error Resume Next
        .Offset(1).Resize(.Rows.Count - 1).SpecialCells(12).EntireRow.Delete
        On Error GoTo 0
        ActiveSheet.AutoFilterMode = False
 
    End With
 
    Application.ScreenUpdating = True
End Sub

 

[PaigeWarner]

You can filter the cells by color, then delete the visible rows.

Thank you Larry! I actually already had the filter by color in the macro so I just needed a VBA code to recognize Light Red Fill and delete because it would be a different amount of lines cells every time.

 

[Larry Haydn]

Sorry, did not check the message board for a few days.

If you select the coloured call, and pull out the cooler palette, you can find the cell interior color in RGB value, which is a combination of 3 colors.
For example, if you type the following in the VBE's Immediate pane:

range("B2").Interior.Color=rgb(122,180,200)
...or...
columns("C").interior.color=rgb(115,70,136)

You can see that these values actually produce the cell interior color.
Interpolating from this, you can find the RGB values for your coloured cell, then use that in your VBA code to accomplish the task of deleting those cells or rows:

IF Range("A" & RowNo).Interior.Color=RGB(255,199,206) Then
    'Do whatever you need here
END IF

 

[MARK858]

@Larry Haydn, you need to use DisplayFormat for that as the cells are conditionally formatted.