As for the yearly discount rate, honestly there is a company wide discount rate

So, someone in the company finance dept should be able to tell you how they want you to determine sub-annual rates.

So it looks like using simple monthly discount rate calculation and picking the lowest NPV works in this case,right?

If the company specifies an annual discount rate of 20%, I suspect that they might be interested in the actual NPV value, at least sometimes, not just the relative order of NPVs for two or more alternatives.

In that case, I would "de-compound" (discount) the annual rate instead of simply dividing it.

For example, a monthly rate for 20% would be NOMINAL(20%,12)/12 or (1+20%)^(1/12)-1. Thus, the monthly rate compounded over 12 periods is 20% annually.

The following example might help.

| A | B | C | D | E | F | G | H | I |

1 | Simple Rate | PV | NPV
| Equal? | | pmt# | | 24 pmts | 36 pmts |

2 | 24 pmts | $106.43 | $106.43 | TRUE | | 0 | Jan'19 | $0.00 | $0.00 |

3 | 36 pmts | $108.38 | $108.38
| TRUE | | 1 | Feb'19 | -$5.42 | -$4.03 |

4 | | |
| | | 2 | Mar'19 | -$5.42 | -$4.03 |

5 | Compounded Rate | PV | NPV | Equal? | | 3 | Apr'19 | -$5.42 | -$4.03 |

6 | 24 pmts | $108.11 | $108.11 | TRUE | | 4 | May'19 | -$5.42 | -$4.03 |

7 | 36 pmts | $110.84 | $110.84 | TRUE | | 5 | Jun'19 | -$5.42 | -$4.03 |

8 | | |
| | | 6 | Jul'19 | -$5.42 | -$4.03 |

9 | Annual Rate | | XNPV | | | 7 | Aug'19 | -$5.42 | -$4.03 |

10 | 24 pmts | | $108.13 | | | 8 | Sep'19 | -$5.42 | -$4.03 |

11 | 36 pmts | | $110.85 | | | 9 | Oct'19 | -$5.42 | -$4.03 |

12 | | | | | | 10 | Nov'19 | -$5.42 | -$4.03 |

13 | | | | | | 11 | Dec'19 | -$5.42 | -$4.03 |

[HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] |

25 | | | | | | 23 | Dec'20 | -$5.42 | -$4.03 |

26 | | | | | | 24 | Jan'21 | -$5.42 | -$4.03 |

27 | | | | | | 25 | Feb'21 | | -$4.03 |

[HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] | [HR][/HR] |

37 | | | | | | 35 | Dec'21 | | -$4.03 |

38 | | | | | | 36 | Jan'22 | | -$4.03 |

<tbody>

</tbody>

Code:

```
Formulas:
B2: =PV(20%/12,24,-130/24,0)
C2: =-NPV(20%/12,H3:H26)
D2: =B2=C2
B3: =PV(20%/12,36,-145/36,0)
C3: =-NPV(20%/12,I3:I38)
D3: =ABS(B3-C3) < 1E-11
B6: =PV(NOMINAL(20%,12)/12,24,-130/24,0)
C6: =-NPV(NOMINAL(20%,12)/12,H3:H26)
D6: =B6=C6
B7: =PV(NOMINAL(20%,12)/12,36,-145/36,0)
C7: =-NPV(NOMINAL(20%,12)/12,I3:I38)
D7: =B7=C7
C10: =-XNPV(20%,H2:H26,G2:G26)
C11: =-XNPV(20%,I2:I38,G2:G38)
G2:G38: actual dates, the same day for each month
H3: =-130/24
I3: =-145/36
Copy H3 into H4:H26
Copy I3 into I4:I38
```

We could avoid the cash flow table in columns F:I by using some trickery in the formulas. But I want to keep the formulas simple in order to focus on the real issue here, namely the calculation of the NPV. And the cash flow table might make that clearer.

The calculations in column B demonstrate that for equal monthly cash flows, we could use the PV function instead of the NPV function. Column D demonstrates that the results are the same, at least to 11 decimal places (14 significant digits).

But the primary purpose of the example is to contrast, in column C, the NPV calculations based on simple and compounded rates, compared to the XNPV calculation based on the annual discount rate (20%).

If you used the simple monthly rate (20%/12) in C2 and C3 and a colleague used XNPV with the annual rate (20%) in C10 and C11, the results are very different. No surprise. But since the colleague used the corporate-mandated rate, you might have some difficult explaining to do.

However, if you used the compounded monthly rate (NOMINAL(20%,12)/12) in C6 and C7, the results are very similar to the XNPV results. The results are somewhat different. But the explanation is easy: NPV assumes equal periods ("monthly"), whereas XNPV uses the exact number of days between periods, which varies from 28 to 31.