Number to Timestamp

[workindan]

Hello,

I'm using vba to try and convert some numbers to timestamps....

I'd like what I have:

0
30
130
200
230

to look like:

00:00
00:30
01:30
02:00
02:30

Any ideas?

 

[jim may]

Paste this code into your Sheet Module; Note Current Range in Red - Change to Suit...

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim TimeStr As String

On Error GoTo EndMacro
If Application.Intersect(Target, Range("A1:A5")) Is Nothing Then
    Exit Sub
End If
If Target.Cells.Count > 1 Then
    Exit Sub
End If
If Target.Value = "" Then
    Exit Sub
End If

Application.EnableEvents = False
With Target
If .HasFormula = False Then
    Select Case Len(.Value)
        Case 1 ' e.g., 1 = 00:01 AM
            TimeStr = "00:0" & .Value
        Case 2 ' e.g., 12 = 00:12 AM
            TimeStr = "00:" & .Value
        Case 3 ' e.g., 735 = 7:35 AM
            TimeStr = Left(.Value, 1) & ":" & _
            Right(.Value, 2)
        Case 4 ' e.g., 1234 = 12:34
            TimeStr = Left(.Value, 2) & ":" & _
            Right(.Value, 2)
        Case 5 ' e.g., 12345 = 1:23:45 NOT 12:03:45
            TimeStr = Left(.Value, 1) & ":" & _
            Mid(.Value, 2, 2) & ":" & Right(.Value, 2)
        Case 6 ' e.g., 123456 = 12:34:56
            TimeStr = Left(.Value, 2) & ":" & _
            Mid(.Value, 3, 2) & ":" & Right(.Value, 2)
        Case Else
            Err.Raise 0
    End Select
    .Value = TimeValue(TimeStr)
End If
End With
Application.EnableEvents = True
Exit Sub
EndMacro:
MsgBox "You did not enter a valid time"
Application.EnableEvents = True
End Sub

 

[workindan]

I just came back to say I'd figured it out - and Jim your method looks great, I'll have to hold on to that one.

But this seems to work for half hour intervals as digits and turning them into numbers:

str = 230
Format(str / 2400, "hh") & ":" & Right(str, 2)

--> 02:30

 

[West Man]

An alternative: =((RIGHT(A1,2)+0)+(INT(A1/100)*60))/1440 Format as time

 

[T. Valko]

An alternative: =((RIGHT(A1,2)+0)+(INT(A1/100)*60))/1440 Format as time

Try this one...

=--TEXT(A1,"00\:00")

Format as Time