# of thursdays in a specific month

[aamir]

how to count # of Thursdays in any month given in O2.

btw i found # of days in specific month(O2) by using this formula.

=DAY(DATE(YEAR(O2),MONTH(O2)+1,1)-1)

 

[Peter_SSs]

btw i found # of days in specific month(O2) by using this formula.

=DAY(DATE(YEAR(O2),MONTH(O2)+1,1)-1)

If you have Analysis ToolPak installed & activated:
=DAY(EOMONTH(O2,0))

Without Analysis ToolPak you can slightly shorten yours to:
=DAY(DATE(YEAR(A1),MONTH(A1)+1,0))

For your other question, this may give you something you can work with:
http://www.mrexcel.com/forum/showpost.php?p=1980395&postcount=4

 

[Haseeb Avarakkan]

Hello,

Here is the one way.

=SUMPRODUCT(--(WEEKDAY(ROW(INDEX(A:A,O2-DAY(O2)+1):INDEX(A:A,EOMONTH(O2,0))))=5))

If you are using 2003- this will require analysis ToolPak installed to work EOMONTH.

 

[Libra0099]

Hope this will serve your purpose

Excel Workbook
	A	B	C	D
1	Start	End	Thursday	No of thursdays
2	1-Jan	31-Jan	5	4
3	1-Feb	28-Feb	5	4
4	1-Mar	31-Mar	5	5
5	1-Apr	30-Apr	5	4
6	1-May	31-May	5	4
7	1-Jun	30-Jun	5	5
8	1-Jul	31-Jul	5	4
9	1-Aug	31-Aug	5	4
10	1-Sep	30-Sep	5	5
11	1-Oct	31-Oct	5	4
12	1-Nov	30-Nov	5	4
13	1-Dec	31-Dec	5	5
Sheet1

 

[ukmikeb]

Hi

A variation on Haseeb's -

=SUMPRODUCT(--(WEEKDAY(ROW(INDIRECT(EOMONTH($A$2,-1)+1&":"&EOMONTH($A$2,0))),2)=4))

where the date in A2 can be any date in the required month

NB with the same caveat about Excel 2003

hth

 

[aamir]

If you have start date in A1 and end date in B1 this formula will give you a count of Mondays between those two dates (inclusive)

=INT((WEEKDAY(A1-5)+B1-A1)/7)

change the 2 to get other days (1=Sun through to 7 = Sat)

I appreciate the work by Mr. Peter and Mr. Gohar and the above formula also works for two days given in different cells. But my problem is that i only have one date and that's located on O2 and i have to find # of Thursdays in given month btw O2 date is always 1st of each month.

 

[Haseeb Avarakkan]

Try the post #3

 

[barry houdini]

.....i only have one date and that's located on O2 and i have to find # of Thursdays in given month btw O2 date is always 1st of each month.

Try this formula, I believe it will give you the same result as Haseeb's suggestion

=4+(DAY(O2+34)< WEEKDAY(O2+2))