On Passwords...but not against the forum rules

[shajueasow]

Hi,
How can I allow the user to give his own password, other than using
If PW<>"password" then Exit Sub
like code.

I would like to
1)get password from the user and store it and
2)then check it with the password next time given by the user

TIA

 

[Andrew Poulsom]

See if this gets you started:

Sub StorePassword()
    Dim Ans As Variant
    Ans = InputBox("Choose a password", "Password")
    If Ans = "" Then Exit Sub
    ThisWorkbook.Names.Add Name:="Password", RefersTo:=Ans
    ThisWorkbook.Names("Password").Visible = False
End Sub

Sub GetPassword()
    Dim Test As Name
    Dim Ans As Variant
    On Error Resume Next
    Set Test = ThisWorkbook.Names("Password")
    If Err <> 0 Then
        Err.Clear
        MsgBox "No password set"
        Exit Sub
    End If
    On Error GoTo 0
    Ans = InputBox("Enter password", "Password")
    If Ans = "" Then
        Exit Sub
    ElseIf Ans = Evaluate("=Password") Then
        MsgBox "Password correct"
    Else
        MsgBox "Incorrect password"
    End If
End Sub

 

[shajueasow]

Thanks A Lot for this code.
Had a lot of stuff (for me) to play upon.
Thanks A lot