Open a pdf file based on partial text of a cell value

[kamranyd]

It open pdf based on cell value in cell F10. I would like to open a pdf file in certain folder only if the pdf file name start with F10 cell value. Below code work fine but works ONLY if the pdf file name is exactly the same in F10 cell value.

How can I open the pdf file if the pdf file name started with cell F10 value?


These codes open pdf file based on cell value, I need these codes open pdf who has numbers

Sub inv_PDF_File()

   Dim FileNameRef As String, Prompt As String, myPath As String
   Dim ret As Variant
  
      FileNameRef = Application.WorksheetFunction.Text(Range("F10"), "0000")
      myPath = "C:\"
    
    On Error Resume Next
    ThisWorkbook.FollowHyperlink myPath & FileNameRef & ".pdf"
    
    If Err.Number <> 0 Then
    Prompt = "Invoice Number [-]> " & FileNameRef & " <[-]" & vbNewLine & _
    "NOT FOUND IN BELOW LOCATION OR LOCATION DOESN'T EXIT." & vbNewLine & _
    "Click to explore folder location C:\"
  
    Const TITLE = "PDF file Search"
    Const BUTTONS = vbExclamation
            
    Dim lRet As VbMsgBoxResult
    Dim sLinksArray(0 To 0, 1) As String
  
    sLinksArray(0, 0) = "C:\":            sLinksArray(0, 1) = "C:\"
    
    lRet = HyperlinkMsgBox(Prompt, sLinksArray, BUTTONS, TITLE)
    
End If
End Sub

 

[John_w]

I would like to open a pdf file in certain folder only if the pdf file name start with F10 cell value.

Incorporate this into your code:

    Dim PDFfile As String
    
    PDFfile = Dir(myPath & Range("F10").Value & "*.pdf")
    If PDFfile <> vbNullString Then
        ThisWorkbook.FollowHyperlink myPath & PDFfile
    End If

 

[kamranyd]

Incorporate this into your code:

    Dim PDFfile As String
   
    PDFfile = Dir(myPath & Range("F10").Value & "*.pdf")
    If PDFfile <> vbNullString Then
        ThisWorkbook.FollowHyperlink myPath & PDFfile
    End If

Thanks for help, please if you show how to incorporate with my codes, I am trying but nothing happen. thanks once again

 

[John_w]

Like this:

Sub inv_PDF_File()

    Dim FileNameRef As String, Prompt As String, myPath As String
    Dim ret As Variant
    Dim PDFfile As String
    
    FileNameRef = Range("F10").Value
    myPath = "C:\"
    PDFfile = Dir(myPath & FileNameRef & "*.pdf")
    If PDFfile <> vbNullString Then
        ThisWorkbook.FollowHyperlink myPath & PDFfile
    Else
        Prompt = "Invoice Number starting with [-]> " & FileNameRef & " <[-]" & vbNewLine & _
        "NOT FOUND IN BELOW LOCATION OR LOCATION DOESN'T EXIT." & vbNewLine & _
        "Click to explore folder location C:\"
      
        Const TITLE = "PDF file Search"
        Const BUTTONS = vbExclamation
                
        Dim lRet As VbMsgBoxResult
        Dim sLinksArray(0 To 0, 1) As String
      
        sLinksArray(0, 0) = "C:\":            sLinksArray(0, 1) = "C:\"
        
        ret = HyperlinkMsgBox(Prompt, sLinksArray, BUTTONS, TITLE)
    End If
    
End Sub