Ordering sheets in Excel

[j-a-k]

I want to know if its possible to alphabeticaly order sheets in excel...

I think it can be done with VB, but I have no clue how.

 

[texasalynn]

here is a macro I found on this site.

Sub SortWorksheets()

Dim N As Integer
Dim M As Integer
Dim FirstWSToSort As Integer
Dim LastWSToSort As Integer
Dim SortDescending As Boolean

SortDescending = False

If ActiveWindow.SelectedSheets.Count = 1 Then
    FirstWSToSort = 1
    LastWSToSort = Worksheets.Count
Else
    With ActiveWindow.SelectedSheets
        For N = 2 To .Count
            If .Item(N - 1).Index <> .Item(N).Index - 1 Then
                MsgBox "You cannot sort non-adjacent sheets"
                Exit Sub
            End If
        Next N
        FirstWSToSort = .Item(1).Index
        LastWSToSort = .Item(.Count).Index
     End With
End If

For M = FirstWSToSort To LastWSToSort
    For N = M To LastWSToSort
        If SortDescending = True Then
            If UCase(Worksheets(N).Name) > UCase(Worksheets(M).Name) Then
                Worksheets(N).Move Before:=Worksheets(M)
            End If
        Else
            If UCase(Worksheets(N).Name) < UCase(Worksheets(M).Name) Then
               Worksheets(N).Move Before:=Worksheets(M)
            End If
        End If
     Next N
Next M

End Sub

HTH
texasalynn

 

[j-a-k]

thanks texasalynn


I`m really a n00b at this.. can you tell me where to put it? (step by step if you dont mind)

 

[texasalynn]

No problem! Right click on the sheet tab and select "View Code". That will open the Visual Basic Editor. From the menu select "Insert" and then "Module". Now paste the code I sent into there. Close the visual editor. The macro is ready to run.

HTH
texasalynn

 

[j-a-k]

Thank you very much