OUT OF STACK SPACE error at GetObject line

[adds416]

Hi,
I wrote a 10 line program to import a word table to excel, as shown below.

Sub Method1()
 
Debug.Print Application.MemoryTotal & " available; " & _
            Application.MemoryFree & " free; " & _
            Application.MemoryUsed & " used"
Dim wordTable As Object
Set wordTable = GetObject(ThisWorkbook.Path & "\test.doc")    '<-- error here
With wordTable
    .tables(1).Range.Copy
End With
Sheets(1).Paste 
Set wordTable = Nothing
End Sub

The problem is that i get "Error 28: Out of stack space" whenever I run it, despite below actions
-I dont have any events for any even cascade
-NO fixed-length strings
-NO other procedures in the project
-NO procedure calls in this procedure
-NO other variable except WordTable as Object, which i destroy when i am done with it
-NO nested loops or DoEvents
-NO public declared variables
-NOTHING else open when i run this program

Please help! I am running out of options and I would really like to get this working. Is there a way to track stack space or clear it?
Thanks

 

[VoG]

I don't know why you are getting that error. Try this alternative code

Sub ImportWordTable1()
'Import one table to current sheet
Dim wdDoc As Object
Dim wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")
If wdFileName = False Then Exit Sub '(user cancelled import file browser)
Set wdDoc = GetObject(wdFileName) 'open Word file
With wdDoc
    TableNo = wdDoc.tables.Count
    If TableNo = 0 Then
        MsgBox "This document contains no tables", _
            vbExclamation, "Import Word Table"
    ElseIf TableNo > 1 Then
    TableNo = InputBox("This Word document contains " & TableNo & " tables." & vbCrLf & _
        "Enter table number of table to import", "Import Word Table", "1")
    End If
    With .tables(TableNo)
'copy cell contents from Word table cells to Excel cells
        For iRow = 1 To .Rows.Count
            For iCol = 1 To .Columns.Count
                On Error Resume Next
                Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
                On Error GoTo 0
            Next iCol
        Next iRow
    End With
End With
Set wdDoc = Nothing
End Sub

 

[adds416]

Thanks for the suggestion, but I have already used that code b4 and gave same error.
Nevertheless, I tried it again and crossed my fingers, but fate isnt on my side on this one. Still gives the error on line

Set wdDoc = GetObject(wdFileName) 'open Word file, error at GetObject