Pass data from one userform to another

[GiraffetheGeek]

Hi there

I have a userform that has 20 lines of 4 text boxes and one button on each line.

I want the button to open a second userform that has only one line of 4 text boxes and copy the text in it line of text boxes to the text boxes in the second user form.

I have declared these at the top of the first userform's code

Public NameToPass As String
Public DisToPass As String
Public HelpToPass As String
Public CMToPass As String

The code I have for the button is

Private Sub Btn_Week1Appt1_Click()
    NameToPass = WB_TxtBox_NameWeek1Appt1.Text
    DisToPass = WB_TxtBox_DisWeek1Appt1.Text
    HelpToPass = WB_TxtBox_HelpWeek1Appt1.Text
    CMToPass = WB_TxtBox_CMWeek1Appt1.Text
    Enter_Appt.Show
        
End Sub

And the code I have for the initialise function on the second userform is

Private Sub UserForm_Initialize()
    Box_EnterName.Text = NameToPass
    Box_EnterDis.Text = DisToPass
    Box_EnterHelp.Text = HelpToPass
    Box_EnterCM.Text = CMToPass
End Sub

However nothing is being put into the text boxes on the second userform. I know the varibale NameToPass, DisToPass etc are being populated correctly so I figure it has something to do with going from one form to another.

I suppose I could copy the data to a sheet first and then pull the data from the sheet to the new user form, but would like to avoid that and teach myself how to pass data from one form to another.

Cheers in advance

 

[GTO]

I have declared these at the top of the first userform's code

Public NameToPass As String
Public DisToPass As String
Public HelpToPass As String
Public CMToPass As String

For the moment, move these to the top of a Standard Module.

Am I correct in presuming that the userforms are modeless?

 

[GiraffetheGeek]

If modeless is the default when creating userforms in excel then they are.

I am new to using userforms so am learning as I go.

How do I tell if they are modeless or not?

 

[GTO]

If modeless is the default when creating userforms in excel then they are... How do I tell if they are modeless or not?

No, userforms are Modal by default. This means that you cannot click back onto the worksheet while the form is up. If you show a form in Modeless, then you can change focus (to let's say, the worksheet) while the form is running.

To check or set this property in design mode, with the userform selected, look at the properties window and look for ShowModal.

To set the property during runtime:

UserForm1.Show vbModal
'or 
UserForm.Show vbModeless

I am afraid I was presuming a bit, as I do not normally run multiple forms at the same time.

Mark

 

[GiraffetheGeek]

Cheers, thats very helpful

 

[mikerickson]

This is one way to pass data from one userform to the other.
This is in the first userform's code module

Private Sub CommandButton2_Click()
    UserForm2.Tag = Join(Array(NameToPass, DisToPass, HelpToPass, CMToPass), ",")
    
     UserForm2.Show
End Sub

This is in Userform2's Activate event.

Private Sub UserForm_Activate()
    Dim Arguments As Variant
    
    With Me
        Arguments = Split(.Tag, ",")
        ReDim Preserve Arguments(0 To 3)
        
        .TextBox1 = Arguments(0)
        .TextBox2 = Arguments(1)
        .TextBox3 = Arguments(2)
        .TextBox4 = Arguments(3)
    End With
End Sub

 

[mikerickson]

Or, since you have those variables declared public, scrub the Activate event above and use this in UserForm2.

Private Sub UserForm_Initialize()
    Me.TextBox1.Text = UserForm1.NameToPass
    Me.TextBox2.Text = UserForm1.DisToPass
    Me.TextBox3.Text = UserForm1.HelpToPass
    Me.TextBox4.Text = UserForm1.CMToPass
End Sub

Public variables that are declared in an object's code module (userform,sheet,Thisworkbook) can be treated as properties of that object and can be read or written to as such.