Password protect worksheets

[siafc1]

Hi,

Firstly, this is a college project so it doesn't matter if the workbook isn't 100% secure (although in excel I've heard that isn't possible anyway).

I want to protect certain worksheets with password protection. The basic excel protection isn't satisfactory because it ruins my macros. I want to simply protect access to a worksheet with a password.

For example my 5th sheet (named "Accounts") is one I definately want to protect with a password.

The tricky bit:

To access the "Accounts" sheet, I want the user to click on a button that has a macro attached to it that takes them to "Accounts" (I've already got this) rather than the tabs at the bottom.

So is there a way in which when the user clicks on the "Accounts" macro, they have to type in a password before they get to "Accounts"?

ps. Also, is there any way I can get rid of the tabs at the bottom so the user can only use my macros to navigate around the workbook?

thanks, any help would be appreciated greatly.

 

[shajueasow]

Hi siafc1,

Sub getaccounts()
    Sheets("Accounts").Select
    Sheets("Accounts").Unprotect
End Sub

The above is a simple macro to make a user to use password to unprotect the sheet (named accounts in this regard). (if he is familiar to Excel ways only as I do. )
And regarding the tabs at bottom... I think help is on the way

 

[Smitty]

To hide all sheets except for your macro sheet:

Private Sub Workbook_Open()
    Dim ws As Worksheet
        '   Hide worksheet tabs
        ActiveWindow.DisplayWorkbookTabs = False
            
        For Each ws In ActiveWorkbook.Worksheets
            '   Macro navigation sheet
            If ws.Name <> "Dashboard" Then
                ws.Visible = xlSheetHidden
            End If
        Next ws
        
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ActiveWindow.DisplayWorkbookTabs = True
End Sub

To get to the account sheet and require a password (using an ActiveX button):

Private Sub CommandButton1_Click()
    Dim ans As String
        ans = InputBox("Please enter the password", "Password required")
        
        If ans <> "yomama" Then
            Exit Sub
        Else
            With Sheets("Accounts")
                .Visible = True
                .Activate
            End With
        End If
End Sub

HTH,

Smitty

 

[siafc1]

Thanks for the replies.

Thanks Smitty, that's all I needed