Pivotfilter with variations of similar item

[muhleebbin]

Hi,

Can someone help me with the following code?

Sub refreshpivot()

Dim ws As Worksheet
Dim pvt As PivotTable
Dim pf As PivotField
Set pvt = Worksheets("GL R Pivot").PivotTables("PivotTable1")
Set pf = pvt.PivotFields("Person/Description")

Application.ScreenUpdating = False
ThisWorkbook.RefreshAll

    On Error Resume Next
    With pf
        .ClearAllFilters
        .PivotItems("(blank)").Visible = False
        .PivotItems("").Visible = False
        .PivotItems("Net Change").Visible = False
    End With

Application.ScreenUpdating = True

End Sub

The issue i'm having is that "Net Change" item is really "Net Change = -#####", is it possible so that it finds any and all instances of the "Net Change" item?

Thanks in advance for your assistance

 

[muhleebbin]

Solved it with

Sub refreshpivot()

Dim ws As Worksheet
Dim pvt As PivotTable
Dim pf As PivotField
Dim pi As PivotItem
Dim str As String
Set pvt = Worksheets("GL R Pivot").PivotTables("PivotTable1")
Set pf = pvt.PivotFields("Person/Description")
str = "Net Change"

Application.ScreenUpdating = False
ThisWorkbook.RefreshAll

    On Error Resume Next
    With pf
        .ClearAllFilters
            For Each pi In .PivotItems
                If pi.Name Like "*" & str & "*" Then
                    pi.Visible = False
                Else
                    pi.Visible = True
                End If
            Next pi
        .PivotItems("(blank)").Visible = False
        .PivotItems("").Visible = False
    End With

Application.ScreenUpdating = True

End Sub