Problem with autofill function?

[Mugalh01]

Morning all,

Could you please help me out with my code - I'm simply trying to fill down from the cell with a formula (Rng2 in my code) but I'm getting error upon error.
Rng2.AutoFill Destination:=Range("E2:E14"), Type:=xlFillDefault - gives me an error; as does

Rng2.Select
Selection.AutoFill Destination:=Range("E2:E14"), Type:=xlFillDefault

My full code is as below - any help will be greatly appreciated.

Sub Subpanel_tab()

Dim wsDestin As Worksheet
Dim Rng1 As Range
Dim Rng2 As Range
Dim Rng3 As Range

Set wsDestin = Sheets("Subpanel Coverage")

With wsDestin
Set Rng1 = wsDestin.Range("D2")
Set Rng2 = wsDestin.Range("E2")
Set Rng3 = wsDestin.Range("F2")

Rng1.FormulaR1C1 = _
        "=LEFT(RC[-3],SEARCH(""_"",RC[-3],SEARCH(""_"",RC[-3])+1)-1)"
Rng2.FormulaR1C1 = _
        "=IFERROR(MID(SUBSTITUTE(RC[-4],""_"",""^^"",2),FIND(""^^"",SUBSTITUTE(RC[-4],""_"",""^^"",2))+2,LEN(RC[-4])),""subpanel"")"
Rng2.AutoFill Destination:=Range("E2:E14"), Type:=xlFillDefault
Rng3.FormulaR1C1 = _
        "=IFERROR(LEFT(RC[-1],FIND(""_GENE"",RC[-1])-1),RC[-1])"
    Rng3.Select
    Selection.AutoFill Destination:=Range("F2:F14"), Type:=xlFillDefault
    Application.CutCopyMode = False

    End With

End Sub

Thank you.

 

[Fluff]

Try

Sub Subpanel_tab()

Dim wsDestin As Worksheet
Dim Rng1 As Range
Dim Rng2 As Range
Dim Rng3 As Range

Set wsDestin = Sheets("Subpanel Coverage")

With wsDestin
   Set Rng1 = .Range("D2")
   Set Rng2 = .Range("E2")
   Set Rng3 = .Range("F2")
   
   Rng1.FormulaR1C1 = _
           "=LEFT(RC[-3],SEARCH(""_"",RC[-3],SEARCH(""_"",RC[-3])+1)-1)"
   Rng2.FormulaR1C1 = _
           "=IFERROR(MID(SUBSTITUTE(RC[-4],""_"",""^^"",2),FIND(""^^"",SUBSTITUTE(RC[-4],""_"",""^^"",2))+2,LEN(RC[-4])),""subpanel"")"
   Rng2.AutoFill Destination:=.Range("E2:E14"), Type:=xlFillDefault
   Rng3.FormulaR1C1 = _
           "=IFERROR(LEFT(RC[-1],FIND(""_GENE"",RC[-1])-1),RC[-1])"
   Rng3.AutoFill Destination:=.Range("F2:F14"), Type:=xlFillDefault
   Application.CutCopyMode = False

End With

End Sub

 

[MARK858]

Personally I see no need to use autofill at all as there appears to be no reason not to apply the formula directly to the ranges...

Sub Subpanel_tab()

    Set wsDestin = Sheets("Subpanel Coverage")

    With wsDestin

        .Range("D2").FormulaR1C1 = _
        "=LEFT(RC[-3],SEARCH(""_"",RC[-3],SEARCH(""_"",RC[-3])+1)-1)"
        
        .Range("E2:E14").FormulaR1C1 = _
        "=IFERROR(MID(SUBSTITUTE(RC[-4],""_"",""^^"",2),FIND(""^^"",SUBSTITUTE(RC[-4],""_"",""^^"",2))+2,LEN(RC[-4])),""subpanel"")"

        .Range("F2:F14").FormulaR1C1 = _
        "=IFERROR(LEFT(RC[-1],FIND(""_GENE"",RC[-1])-1),RC[-1])"


    End With

End Sub

I also don't see the need for the line below

Application.CutCopyMode = False

 

[Mugalh01]

Nice one Mark and Fluff,
Both codes work perfectly.

And you are right, i did not need the 'Application.CutCopyMode = False'

Thanks again

 

[Fluff]

Glad we could help & thanks for the feedback