Programmatically allowing access to Visual Basic Project

[iangorm]

Hi,

I am developing an application where I programmatically remove some macros from workbook A, using a macro in workbook B prior to saving workbook A.

In Excel 2003 it seems that the default security level for macros is set to NOT trust "access to Visual Basic Project" programmatically. This stops my program to remove the macros in workbook A from running.

Does anyone know of some VBA code that I can run from workbook B to change the check box in macro security to allow programmatic "access to Visual BAsic Project"?

Once the macros are removed from workbook A then I want to return the Excel security setting to NOT trust "access to Visual Basic Project" programmatically.

I know how to do this manually, but would like to maximise security by only lowering security for the time required.

Hoping someone can help.

All the Best,

Ian

 

[Tom Urtis]

It needs to be done locally by the user(s) of the computer(s) that get the program, instituted in 2002. See this link from yesterday where I posted code to a related question regarding how to check programmatically if the user has granted trusted access to the VBE.

http://www.mrexcel.com/board2/viewtopic.php?t=177782&highlight=1

 

[Tazguy37]

The only way I can think of to do this at the moment is with SendKeys.

I tried:

    SendKeys "%toisss%st%v", True
    Application.Wait Now + TimeValue("00:00:01")
    SendKeys "{TAB}~{ESC}{ESC}{ESC}", True

but I still end up back at the Trusted sources tab.

 

[Ivan F Moala]

You can't lower the security setting programtically.
This best way IMHO is as TazGuy & Tom have alluded to is to allow the users to set this for you ..... eg

Option Explicit

http://xcelfiles.homestead.com/Security.html

Sub CheckSecurity()
Dim Q As Integer

TryNow:
'// Check security settings 1st!
If Not SecuritySet(ThisWorkbook) Then
    Q = MsgBox("These routines access your VBA modules" & vbCrLf & vbCrLf & _
        "Please set your security to [Trust access to Visual basic Project]." & vbCrLf & vbCrLf & _
        "Select [Security] > " & vbCrLf & vbTab & "Tab [Trusted Publishers] > " & _
        vbTab & vbCrLf & vbTab & vbTab & "Click [Trust access to Visual basic Project]" & vbCrLf & vbCrLf & _
        "You will be taken to these settings after clicking OK" & vbCrLf & _
        "Click cancel to skip setting this.", vbCritical + vbOKCancel, "Security settings")
    If Q = vbOK Then
        With Application
            .SendKeys "t"
            .CommandBars.FindControl(ID:=3627).Execute
        End With
        GoTo TryNow
    End If
End If

End Sub

Function SecuritySet(WBk As Workbook) As Boolean
Dim objVbaProj As Object

    '// Check Security
    On Error Resume Next
    '// Note LateBinding so NO reference to Extensibilty Lib Required
    Set objVbaProj = WBk.VBProject
    
    '// Check Version
    If CDbl(Val(Application.Version)) > 9 Then
        SecuritySet = Not CBool(Err.Number)
    Else
        SecuritySet = True
    End If
    On Error GoTo 0

End Function