Quick and Easy VBA Fix/Help?

[GaryG9595]

Hello Everyone,
Currently I have a VBA Code that I use to change the names of all the tabs to a specific cell in the worksheet. See VBA Code 1. below. In this case it's "A2". I obvioulsy can change that cell to point other cells for future changes.
My question is, how can this code be modified to exclude renaming certain sheets?

I have another code the splits the sheets into their own file folder excluding the "Master Data" and "Pricing" sheets.
I have tried to blend the codes to get it to work, and I can't figure it out. I am still learning.
This was part of the code that I tried.
If xWS.Name <> "Master Data" And xWS.Name <> "Pricing"

I need to rename all the sheets to cell "DO2" excluding these two sheets "Master Data" and "Pricing"

VBA Code 1.
Sub RenameTabs()
For i = 1 To Sheets.Count
If Worksheets(i).Range("A2").Value <> "" Then
Sheets(i).Name = Worksheets(i).Range("A2").Value
End If
Next
End Sub

Thanks in advance,
Gary

 

[Fluff]

How about

Sub RenameTabs()
   Dim Ws As Worksheet
   
   For Each Ws In Worksheets
      If Ws.Name <> "Master Data" And Ws.Name <> "Pricing" Then
         If Ws.Range("DO2").Value <> "" Then Ws.Name = Ws.Range("DO2").Value
      End If
   Next Ws
End Sub

 

[offthelip]

try this:

Sub RenameTabs()
For i = 1 To Sheets.Count
If Worksheets(i).Name <> "Master Data" And Worksheets(i).Name <> "Pricing" Then
    If Worksheets(i).Range("A2").Value <> "" Then
    Sheets(i).Name = Worksheets(i).Range("A2").Value
    End If
End If
Next
End Sub

 

[mumps]

Try this macro. Add any other sheet names you want to exclude to the array.

Sub RenameTabs()
    Application.ScreenUpdating = False
    Dim arr As Variant, i As Long
    arr = Array("Master Data", "Pricing")
    For i = 1 To Sheets.Count
        If IsError(Application.Match(Sheets(i).Name, arr, 0)) Then
            If Worksheets(i).Range("A2").Value <> "" Then
                Sheets(i).Name = Worksheets(i).Range("A2").Value
            End If
        End If
    Next
    Application.ScreenUpdating = False
End Sub

 

[GaryG9595]

Thank you all... You all are the best.
All of them worked and hopefully this will help others in the future as well.
I ended up using mumps suggestion as it was easier to add multiple sheets to exclude.
Thanks again for all your help.
Gary

 

[mumps]

Glad we could help.

 

[Fluff]

If you want to exclude multiple sheets, another option is

Sub RenameTabs()
   Dim Ws As Worksheet
   
   For Each Ws In Worksheets
      Select Case Ws.Name
         Case "Master Data", "Pricing"
         Case Else
            If Ws.Range("DO2").Value <> "" Then Ws.Name = Ws.Range("DO2").Value
      End Select
   Next Ws
End Sub