Remove data from log on cancellation

[Drawleeh]

I have some code that colours in a row of information and then stores the date and the user that coloured in said row of information on a log.

That is all well and good but I would like to somehow figure out how to reverse said process. Currently if you use the code again on the same selection the colour changes back to 'no fill' but unfortunately I'm not sure how to remove that same information that was sent to the log initially. Any ideas?

Sub CompleteLine()
Dim RCount As Integer
Dim SheetName As String

SheetName = ActiveSheet.Name

RCount = Selection.Columns.Count

If Selection.Interior.Color = 5296274 Then
Selection.Interior.ColorIndex = 0

Else

If RCount = 16384 And Selection.Interior.Color <> 5296274 Then
Selection.Interior.Color = 5296274
    With Sheets("Log")
    .Cells(1, 1).End(xlDown).Offset(1) = Format(Date, "dd/mm/yyyy")
    .Cells(1, 2).End(xlDown).Offset(1) = Environ("Username")
    .Cells(1, 2).End(xlDown).Offset(0, 1) = ActiveSheet.Name

    
End With
End If
End If
End Sub

 

[rlv01]

Not tested.

Sub CompleteLine()
    Dim RCount As Integer
    Dim SheetName As String
    Dim LogEntryID As String, LogSearchRange As Range, R As Range

    SheetName = ActiveSheet.Name
    RCount = Selection.Columns.Count

    LogEntryID = SheetName & "!" & Selection.Address(False, False)

    If Selection.Interior.Color = 5296274 Then
        Selection.Interior.ColorIndex = 0

        With Worksheets("Log")
            Set LogSearchRange = Application.Intersect(.UsedRange, .Columns(4))
            Set R = LogSearchRange.Find(What:=LogEntryID, LookAt:=xlWhole)
            If Not R Is Nothing Then
                R.EntireRow.Delete Shift:=xlUp
            End If
        End With
    Else
        If RCount = 16384 And Selection.Interior.Color <> 5296274 Then
            Selection.Interior.Color = 5296274
            With Sheets("Log")
                .Cells(1, 1).End(xlDown).Offset(1).Value = Format(Date, "dd/mm/yyyy")
                .Cells(1, 2).End(xlDown).Offset(1) = Environ("Username")
                .Cells(1, 2).End(xlDown).Offset(0, 1) = ActiveSheet.Name
                .Cells(1, 2).End(xlDown).Offset(0, 2) = LogEntryID
            End With
        End If
    End If
End Sub