Removing brackets and spaces from numbers from within a cell

[jrortiz_2]

I have a spreadsheet with different numbers containing brackets in the following format:
A1 117 (168)
A2 79 (90)

The spreadsheet contains loads of this number.
Is the a way to remove the bracket and extract the specific number that I want and shows the below only:
A1 168
A2 90

Thanks appreciate your help

 

[peterhinton]

try =RIGHT(MID(A1,FIND("(",A1),FIND(")",A1)-FIND("(",A1)),((FIND(")",A1))-(FIND("(",A1))-1))+0

or even =MID(A1,(FIND("(",A1)+1),((FIND(")",A1))-(FIND("(",A1)+1)))+0

 

[AliGW]

Maybe this:

=LEFT(A1,2)&" "&MID(A1,FIND("(",A1),FIND(")",A1)-FIND("(",A1)+1)

 

[jrortiz_2]

Hey Peter
works wonder. Saves me a lot of time
Appreciate your help.Thanks

 

[jrortiz_2]

Thanks AliGW. Tried it but that doesn't give me the number I'm trying to get. Appreciate it though

 

[AliGW]

That's because I thought that the A1 and A2 were part of the number rather than cell references.

This on its own will work fine:

=MID(A1,FIND("(",A1),FIND(")",A1)-FIND("(",A1)+1)

 

[deciog]

My contribution

=0+SUBSTITUTE(MID(A1,FIND("(",A1)+1,5),")","")

Décio

 

[Rick Rothstein]

This should work...

As a TEXT Number: =REPLACE(LEFT(A1,LEN(A1)-1),1,FIND("(",A1),"")

As a REAL Number: =0+REPLACE(LEFT(A1,LEN(A1)-1),1,FIND("(",A1),"")

 

[jrortiz_2]

Thanks Guys. All good

 

[AliGW]

You're welcome!