Removing row if there is not a specific text in columns

[bloomingflower]

Hi,

Please help me make a code that will be asking for name and then if this name is not present from A - H column, macro should remove this row. I have such code, but it is not working. I think that there is a problem with selecting range, but amount of rows differs, so I decided to choose the whole column.

Sub Removerows()
Application.ScreenUpdating = False
Name = InputBox("Enter name")

Dim xRow As Range
    Dim rng As Range
    Dim WorkRng As Range
    On Error Resume Next
    Set WorkRng = Range("A:H").Select
    Application.ScreenUpdating = False
    For i = WorkRng.Rows.Count To 1 Step -1
        Set xRow = WorkRng.Rows(i)
        Set rng = xRow.Find(Name, LookIn:=xlValues)
        If rng Is Nothing Then
            xRow.Delete
        End If
    Next
Application.ScreenUpdating = True

End Sub

 

[MARK858]

Test the code below on a copy of your sheet as you are deleting data.

Sub Removerows()
    Dim myName As String, i As Long
    Application.ScreenUpdating = False
 
    myName = InputBox("Enter name")

 
    For i = Columns("A:H").Find("*", , xlValues, , xlByRows, xlPrevious).Row To 1 Step -1
        If IsError(Application.Match(myName, Intersect(Rows(i), Columns("A:H")), 0)) Then Rows(i).Delete
    Next

    Application.ScreenUpdating = True

End Sub

 

[bloomingflower]

Test the code below on a copy of your sheet as you are deleting data.

Sub Removerows()
    Dim myName As String, i As Long
    Application.ScreenUpdating = False

    myName = InputBox("Enter name")


    For i = Columns("A:H").Find("*", , xlValues, , xlByRows, xlPrevious).Row To 1 Step -1
        If IsError(Application.Match(myName, Intersect(Rows(i), Columns("A:H")), 0)) Then Rows(i).Delete
    Next

    Application.ScreenUpdating = True

End Sub

Thank you, it works great, but it is removing headers as well, could you please tell me how to change it so it takes all rows from 2?

 

[MARK858]

For i = Columns("A:H").Find("*", , xlValues, , xlByRows, xlPrevious).Row To 2 Step -1

Only reason it was 1 in the code is that is what you had it set as in post #1 so I had to assume that you had no headers as it wasn't stated otherwise.

 

[bloomingflower]

For i = Columns("A:H").Find("*", , xlValues, , xlByRows, xlPrevious).Row To 2 Step -1

Only reason it was 1 in the code is that is what you had it set as in post #1

Thank you very much, it works perfectly

 

[MARK858]

You're welcome