Rename files in directory from column B

[jeffreybrown]

I've seen this before but can't seem to locate it.

I would like to pull files from a directory into column A and then from column B I will rename those files and then I would like to rename the files from what is in column B.

Here is the code which I use to capture the file names in column A.

Sub ListFilesNames()
    Dim strTemp As String, MyPath As String, myFile As String
    Dim intCount As Integer, f()

    intCount = 0
    MyPath = ActiveWorkbook.Path & Application.PathSeparator
    myFile = "*.*"
    strTemp = Dir(MyPath & myFile)

    Do While strTemp <> Empty
        intCount = intCount + 1
        ReDim Preserve f(1 To intCount)
        f(intCount) = strTemp
        strTemp = Dir
    Loop

    With Sheets("Sheet1")
        .Range("A:A").Clear
        .Range("A1").Resize(UBound(f), 1).Value = WorksheetFunction.Transpose(f)
    End With
End Sub

 

[AlphaFrog]

Sub Rename_Files()

    Dim cell As Range, MyPath As String

    MyPath = ActiveWorkbook.Path & Application.PathSeparator
    
    For Each cell In Range("A1", Range("A" & Rows.Count).End(xlUp))
        If cell.Offset(, 1) <> "" Then
            Name MyPath & cell.Value As MyPath & cell.Offset(, 1).Value
        End If
    Next cell

End Sub

 

[jeffreybrown]

Thanks AlphaFrog...works great

 

[AlphaFrog]

You're welcome Jeff. Glad it worked for you.

 

[anhtelecom]

You're welcome Jeff. Glad it worked for you.

I found it failed with my case when the name lists in both column A and B are in Vietnamese language ( unicode ), the error notification is run-time error "52" bad file name or number".
How do I edit this script to make it works as all my file names are in Vietnamese language

 

[AlphaFrog]

Make sure your file names do not include any of these characters

\ / : * ? " < > |


There are other characters that may work but should be avoided.

¥ = + ; ^ , [ ]

This is not an exhaustive list.

Error Message: Filename is Invalid or Cannot Contain Any of the Following Characters

 

[400396]

hi,

i try to get the names from my directory to colum a but i get

"run time error 1004"

and when i try to debug there is a problem with this line.

" .Range("A:A").Clear
.Range("A1").Resize(UBound(f), 1).Value = WorksheetFunction.Transpose(f)
"

can someone help?