Repeating a Macro across an Entire Workbook

[Nicole_Michelle01]

I have 5 worksheets (Sheet1, Sheet2, Sheet3, Sheet4, Sheet5) and I want the following macro run for each worksheet:

Sub SetupFile()
For intcount = 1 To 256
If InStr(1, Cells(1, intcount), "userpsswd") > 0 Then
Cells(1, intcount).EntireColumn.Delete
End If
Next intcount
Columns("A:A").Select
Selection.Insert Shift:=xlToRight
Range("A1").Select
ActiveCell.FormulaR1C1 = "Review Notes"
Columns("A:A").Select
Selection.Columns.AutoFit
Columns("E:E").Select
Selection.Insert Shift:=xlToRight
Range("E1").Select
ActiveCell.FormulaR1C1 = "Dept."
End Sub

And also, if I want to add additional keywords to the InStr row ie "userpsswd" "psswd_expdate" "psswd_createdate", what would that look like?

thanks!

 

[Nicole_Michelle01]

yes exact matches only, and the code works for everything except emp_title; it is deleting all other columns exactly

 

[Barrie Davidson]

How about this code instead (looks for exact match only)?

Option Explicit
Sub SetupAllFiles()
Dim ws As Worksheet
Dim SearchWord, i As Integer

Application.ScreenUpdating = False
SearchWord = Array("keyword1", "keyword2", "keyword3", "keyword4")
For Each ws In ActiveWorkbook.Worksheets
    For i = 0 To UBound(SearchWord)
        Call SetupFile(SearchWord(i), ws)
    Next i
    ws.Columns("A:A").Insert Shift:=xlToRight
    ws.Range("A1").FormulaR1C1 = "Review Notes"
    ws.Columns("A:A").Columns.AutoFit
    ws.Columns("E:E").Insert Shift:=xlToRight
    ws.Range("E1").FormulaR1C1 = "Dept."
Next ws
Application.ScreenUpdating = True
End Sub


Sub SetupFile(KeywordPassed, ActiveWs As Worksheet)
Dim intcount As Integer

For intcount = 1 To 256
    If ActiveWs.Cells(1, intcount) = KeywordPassed Then
        ActiveWs.Cells(1, intcount).EntireColumn.Delete
    End If
Next intcount
End Sub

 

[Nicole_Michelle01]

i'll give it a shot...

 

[Nicole_Michelle01]

it works perfectly, you're the best, thanks!