Restart Sub on condition

[Wooders]

I have a Sub that checks a workbook for duplicate worksheets and deletes them. The problem is that after removing the duplicate I want to restart the sub to make sure there are no more duplicates. I tried to use a command just to go to the Sub start but when the Sub completes it then goes back to where it jumped out of the Sub and gives an Out of Range Error. I also tried just setting my loop counters back to their start values but that didn't work either.
Can anyone help please? My code is -

Sub dupCheck()
Dim sht As Worksheet, i As Integer, j As Integer
'find duplicate sheets by checking Cell C5 using the For Loop
For i = 1 To Sheets.Count - 1
For j = (i + 1) To Sheets.Count
If Sheets(i).Range("C5") = Sheets(j).Range("C5") Then Sheets(j).Delete: dupCheck

Next
Next
End Sub

 

[Akuini]

Hi, @Wooders Welcome to the Forum

'find duplicate sheets by checking Cell C5 using the For Loop

So you use C5 value in each sheet to determine duplicate sheets.
Try this:

Sub a1161231b()
Dim ws As Worksheet
Dim d As Object

Set d = CreateObject("scripting.dictionary")
d.CompareMode = vbTextCompare
For Each ws In Worksheets
    If Not d.Exists(ws.Range("C5").Value) Then
        d(ws.Range("C5").Value) = Empty
    Else
        ws.Delete
    End If
Next
       
End Sub

 

[StephenCrump]

Welcome to the Forum

Akuini's approach avoids your double looping. If you wish, you could modify your approach by looping backwards through the j loop:

For j = Sheets.Count To i + 1 Step -1

This means sheets won't be missed when a sheet is deleted and the subsequent numbering changes. There is no need to have dupCheck calling itself.

 

[Wooders]

Thanks Akuini. I am finding it a bit difficult (as a novice) to understand how your suggestion works (I'm getting there slowly) but it does exactly what I need.

 

[Akuini]

You're welcome, glad to help & thanks for the feedback.
Here's a reference about Dictionary Object:
Excel VBA Dictionary - A Complete Guide - Excel Macro Mastery