Retrieving cell reference for value below threshold in conditional list

[drquesh]

Would be grateful for help adding a conditional filter to an array formula to find the maximum value up to a variable threshold in an unsorted list. I can do it for a whole list using help in other posts, but not for a conditional subset.


Example shown below. For each department, I want to find the name of the individual whose value is closest to or equal to, but not over, to a specific value for their department.

So, for department A with a threshold of 6.2, from the list of 5.6, 3.5 and 6.4, it returns row 2's name, Mike. I need the formula to give the results in cells G2 and G3.

	A	B	C	D	E	F	G
1	Dept	Name	Value		Dept	Threshold	Person
2	A	Mike	5.6		A	6.2	Formula = Mike
3	B	Sarah	8.5		B	2.2	Formula = Sandra
4	A	Lindsey	3.5
5	B	Catherine	4.7
6	B	Sandra	2.2
7	A	Paul	6.4
8	B	Geoff	3.3

<tbody>
</tbody>

I know this is likely to need an array formula using MATCH and INDEX, and probably MIN/MAXs given it is unsorted, but I haven't managed to add a conditional filter to the examples I have found that will work on a whole unsorted list.

For duplicates, I'm happy to just return the first result.

Thanks in advance for your help

Chris
[/HTML][/HTML]

 

[wideboydixon]

Book1
	A	B	C	D	E	F	G
1	Dept	Name	Value		Dept	Threshold	Person
2	A	Mike	5.6		A	6.2	Mike
3	B	Saraj	8.5		B	2.2	Sandra
4	A	Lindsey	3.5
5	B	Catherine	4.7
6	B	Sandra	2.2
7	A	Paul	6.4
8	B	Geoff	3.3
Sheet1

Cell Formulas
Range	Formula
G2	{=INDEX($B$2:$B$8,MATCH(MAX(IF($A$2:$A$8=$E2,IF($C$2:$C$8<=$F2,$C$2:$C$8))),$C$2:$C$8,0))}
Press CTRL+SHIFT+ENTER to enter array formulas.

WBD

 

[Aladin Akyurek]

Row\Col	A​	B​	C​	D​	E​	F​	G​	H​
1​	Dept	Name	Value		Dept	Threshold	Person
2​	A	Mike	5.6​		A	6.2​	Mike	Chris
3​	B	Sarah	8.5​		B	2.2​	Sandra
4​	A	Lindsey	3.5​
5​	A	Chris	5.6​
6​	B	Catherine	4.7​
7​	B	Sandra	2.2​
8​	A	Paul	6.4​
9​	B	Geoff	3.3​

In G2 control+shift+enter, not just enter, copy across as far as needed, and down:

=IFERROR(INDEX($B$2:$B$9,SMALL(IF($A$2:$A$9=$E2,IF($C$2:$C$9=MAX(IF($A$2:$A$9=$E2,IF($C$2:$C$9<=$F2,$C$2:$C$9))),
       ROW($B$2:$B$9)-ROW($B$2)+1)),COLUMNS($G2:G2))),"")

 

[drquesh]

Thank you both. Knew I had the right functions, but just couldn't crack the recipe. Really appreciate the help.

 

[Aladin Akyurek]

Thank you both. Knew I had the right functions, but just couldn't crack the recipe. Really appreciate the help.

You need to evaluate the proposals with care. The first proposal will not only miss ties, but it will also fail under adverse conditions (e.g., hange C3 to 2.2).

 

[wideboydixon]

You need to evaluate the proposals with care. The first proposal will not only miss ties, but it will also fail under adverse conditions (e.g., hange C3 to 2.2).

From the original post:

For duplicates, I'm happy to just return the first result.

The solution provided does exactly as requested. The OP did not request all values in case of a tie. There's also no suggestion that there are no values that will match which I assume is the "adverse conditions". If that's the case then:

=IFERROR(INDEX($B$2:$B$8,MATCH(MAX(IF($A$2:$A$8=$E2,IF($C$2:$C$8<=$F2,$C$2:$C$8))),$C$2:$C$8,0)),"")

Entered as an array formula.

WBD