Return the nearest value in an area

[MartinL]

I am trying to return the Column header based on a variable being closest in value to values in an area table.
That may sound confusing so here is a little data to show you what is being asked for

I have the following variables
Country = Germany
SKU = 1235
Requested price = 36,290
The expected retuned value is: TP2

I attempted to work with this formula but failed miserably: {=INDEX(A3:A5,MATCH(MIN(ABS(C2:E6-Requested Price)),ABS(C2:E6-Requested Price),0))}
I obviously need to include Columns A&B (Country & SKU) somewhere in the formula

Country	SKU	RRP	TP1	TP2
UK	1234​	65,198	45,632	27,000
UK	1235​	65,198	45,632	27,000
France	1234​	54,301	38,011	27,000
Germany	1234​	54,173	24,000	19,800
Germany	1235​	54,173	24,000	19,800

 

[MartinL]

My Bad my example is flawed the example Requested price should say 20,290 for expected returned value to be TP2.
Saw this too late to be able to edit the question.....
sorry for the additional confusion

 

[Fluff]

How about

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H
1	Country	SKU	RRP	TP1	TP2
2	UK	1234	65,198	45,632	27,000		Germany
3	UK	1235	65,198	45,632	27,000		1,235
4	France	1234	54,301	38,011	27,000		20,000	TP2
5	Germany	1234	54,173	24,000	19,800
6	Germany	1235	54,173	24,000	19,800
7
Main

Cell Formulas
Range	Formula
H4	H4	=LET(Fltr,FILTER(C2:E6,(A2:A6=G2)*(B2:B6=G3)),INDEX(C1:E1,XMATCH(MIN(ABS(Fltr-G4)),ABS(Fltr-G4),0)))

 

[MartinL]

Hi @Fluff
I've not come across anything like that before, However I get #NAME error when I try to use your solution.

I'm running Excel for Microsoft 365 MSO (16.0.13127.21656) 32-bit

 

[Fluff]

Ok, you probably don't have the latest updates & so are missing the LET function. Try this instead.

=INDEX(C1:E1,XMATCH(MIN(ABS(FILTER(C2:E6,(A2:A6=G2)*(B2:B6=G3))-G4)),ABS(FILTER(C2:E6,(A2:A6=G2)*(B2:B6=G3))-G4),0))

 

[MartinL]

Hi @Fluff

Whoa! Ok yes that works.
I have raised this with IT, would be good to see your other solution working

Thank you very much.

 

[Fluff]

You're welcome & thanks for the feedback.