RGB to Hue formula

[philhowell]

Hi All,

Does anyone know the formula to convert RGB to Hue?

The formula is here, but i dont know how to convert it to Excel;
http://en.wikipedia.org/wiki/Hue


many thanks

 

[rudfaden]

This formula seems to work. But you beter test it. I'm no expert in this.

=IF(180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))<0;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))+360;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2)))

 

[philhowell]

This formula seems to work. But you beter test it. I'm no expert in this.

=IF(180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))<0;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))+360;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2)))

It errors on the semicolon

 

[rudfaden]

If you are using a US version of Excel then replace the semicolons with regular colons

 

[philhowell]

If you are using a US version of Excel then replace the semicolons with regular colons

thanks.

I had to rounddown, but it's near perfect. thanks.

 

[408wij]

If you are using a US version of Excel then replace the semicolons with regular colons

Replace with a comma, NOT with a colon.

 

[ivarharris]

Hello!
Here's the updated hue formula for the current version of office:
=MOD(180/PI()*ATAN2(2*A2-B2-C2,SQRT(3)*(B2-C2)),360)

Cells A2, B2, and C2 are the RGB values for the color.
A2 = Red
B2 = Green
C2 = Blue

For example:
12 20 255

This would give the result of hue being:
238.3396

This is a very precise measurement of hue.. which can be rounded to 238 instead of the long decimal value

Rounded would look like this for the formula:
=ROUND(MOD(180/PI()*ATAN2(2*A2-B2-C2,SQRT(3)*(B2-C2)),360),0)

 

[ivanlawag]

This formula seems to work. But you beter test it. I'm no expert in this.

=IF(180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))<0;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2))+360;180/PI()*ATAN2(2*A2-B2-C2;SQRT(3)*(B2-C2)))

Hello sir,

i would like you to know that the formula worked well and that i was able to use it in my database paper. I cited this thread in the paper and i am happy that the scientific community accepts this kind of information. here is the link to my paper The Development and Application of a HPTLC-Derived Database for the Identification of Phenolics in Honey. Thank you very much again

 

[lrobbo314]

Just for fun I thought I would expand on this and give a full RGB to HSV conversion formula. It gives you the option to return actual values or nicely formatted HSB values. It also avoids the use of ATAN, PI, SQRT, etc. hopefully to speed up calculation speed.

LAMBDA named formula RGB2HSB

=LAMBDA(
    red,green,blue,[strict],
        LET(
            r,red/255,
            g,green/255,
            b,blue/255,
            sq,SEQUENCE(3),
            fx,LAMBDA(a,b,c,CHOOSE(sq,a,b,c)),
            mx,MAX(r,g,b),
            d,mx-MIN(r,g,b),
            h,CHOOSE(XMATCH(mx,fx(r,g,b),0),(g-b)/d,2+(b-r)/d,4+(r-g)/d)*60,
            s,(d/mx),
                IF(strict,
                    fx(TEXT(h,"#°"),TEXT(s,"#,##0.0%"),TEXT(mx,"#,##0.0%")),
                    fx(h,s,mx)
                )
        )
)

RBG2HSB
	A	B	C	D	E	F	G
1	R	G	B		Strict	0
2	12	20	255		Concise	1
3
4
5						Strict	Concise
6					Hue	238.0247	238°
7					Saturation	0.952941	95.3%
8					Brightness	1	100.0%
9
10
11						Strict	Concise
12					Hue	238.0247	238°
13					Saturation	0.952941	95.3%
14					Brightness	1	100.0%
Data

Cell Formulas
Range	Formula
F6:F8	F6	=LET(r,A2/255,g,B2/255,b,C2/255,f,F1,sq,SEQUENCE(3),fx,LAMBDA(a,b,c,CHOOSE(sq,a,b,c)),mx,MAX(r,g,b),d,mx-MIN(r,g,b),h,CHOOSE(XMATCH(mx,CHOOSE(sq,r,g,b),0),(g-b)/d,2+(b-r)/d,4+(r-g)/d)*60,s,(d/mx),IF(f,fx(TEXT(h,"#°"),TEXT(s,"#,##0.0%"),TEXT(mx,"#,##0.0%")),fx(h,s,mx)))
G6:G8	G6	=LET(r,A2/255,g,B2/255,b,C2/255,f,F2,sq,SEQUENCE(3),fx,LAMBDA(a,b,c,CHOOSE(sq,a,b,c)),mx,MAX(r,g,b),d,mx-MIN(r,g,b),h,CHOOSE(XMATCH(mx,CHOOSE(sq,r,g,b),0),(g-b)/d,2+(b-r)/d,4+(r-g)/d)*60,s,(d/mx),IF(f,fx(TEXT(h,"#°"),TEXT(s,"#,##0.0%"),TEXT(mx,"#,##0.0%")),fx(h,s,mx)))
F12:F14	F12	=RGB2HSB(A2,B2,C2)
G12:G14	G12	=RGB2HSB(A2,B2,C2,F2)
Dynamic array formulas.