Script recognizing bold text?

[marko_v]

I have an excel sheet with a cell which contains several sentences. I should extract three parts of text that are bolded and put them in three separate columns on another sheet. Is there any way to create a script that would recognize bold text so I could copy it then and paste it to another place. Just for the record, I have all together over 200 000 rows to check in over than 20 sheets.

 

[Andrew Poulsom]

See if you can adapt this:

Sub Test()
    Dim Sh As Worksheet
    Dim Rng As Range
    Dim Cell As Range
    Dim i As Integer
    Dim ii As Integer
    Dim c As Integer
    Dim First As Integer
    Dim Last As Integer
    Set Sh = Worksheets("Sheet1")
    With Sh
        Set Rng = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)
    End With
    For Each Cell In Rng
        c = 2
        First = 1
        Last = 1
        For i = 1 To Len(Cell.Value)
            If Cell.Characters(i, 1).Font.Bold = True Then
                If Last < i Then
                    First = i
                    For ii = i To Len(Cell.Value)
                        If Cell.Characters(ii, 1).Font.Bold = False Then
                            Last = ii
                            Rng.Cells(Cell.Row, c).Value = Mid(Cell.Value, First, Last - First)
                            c = c + 1
                            Exit For
                        End If
                    Next ii
                End If
            End If
        Next i
    Next Cell
End Sub

 

[marko_v]

Thank you very much. It works great!