Search arrays and add them together to create a new array

[Octopus15]

Cell A8, C8 and E8 are array formulas which can all vary in length depending on data.
A1 is a table of all of the types possible
K3 and K6 are new criteria I want to join to make a combined array from the individual ones, they are both drop down lists based on the data from table A1

In cell G8 I want to add the two arrays together and get the entire spilled result so I can use it to make a new graph, I can make an Xlookup as shown below but it will not spill the entire array.

=(XLOOKUP(K3,Table3[Type],VSTACK(A8,C8,E8)))+(XLOOKUP(K6,Table3[Type],VSTACK(A8,C8,E8)))

 

[Anthony47]

Maybe, in G8:

=TEXTSPLIT(TEXTJOIN("|",TRUE,VSTACK(IFERROR(CHOOSE(MATCH(K3,Table3[Type],0),A8#,C8#,E8#),""),IFERROR(CHOOSE(MATCH(K6,Table3[Type],0),A8#,C8#,E8#),""))),,"|")

 

[StephenCrump]

@Octopus15, welcome to the Forum!

I interpreted your question the same way as @Anthony47.

Wouldn't it be easier to get your results direct from the dataset, rather than using helper columns for every value in Table3?

	A	B	C	D	E
1					Choice
2					Oranges
3		Original			Pears
4		Data
5		Pears	103		103
6		Apples	7		15
7		Oranges	15		16
8		Apples	8		11
9		Oranges	16		101
10		Oranges	11		102
11		Pears	101		14
12		Apples	2		12
13		Pears	102		13
14		Oranges	14
15		Apples	5
16		Apples	1
17		Apples	3
18		Apples	4
19		Oranges	12
20		Oranges	13
21		Apples	6
22
Sheet1

Cell Formulas
Range	Formula
E5:E13	E5	=FILTER(C5:C21,ISNUMBER(MATCH(B5:B21,Choice,)))
Dynamic array formulas.

Named Ranges
Name	Refers To	Cells
Choice	=Sheet1!$E$2:$E$3	E5

 

[Octopus15]

Maybe, in G8:

=TEXTSPLIT(TEXTJOIN("|",TRUE,VSTACK(IFERROR(CHOOSE(MATCH(K3,Table3[Type],0),A8#,C8#,E8#),""),IFERROR(CHOOSE(MATCH(K6,Table3[Type],0),A8#,C8#,E8#),""))),,"|")

Thank you this has worked, I was stuck on the wrong approach

 

[Anthony47]

Thank you for the feedback

I was stuck on the wrong approach

The approach was not wrong, but you had to use the expanded A8, C8 and A8 range; I preferred going with CHOOSE & MATCH because that allowed a shorter formula.