Search Range array

[Enzo_Matrix]

I have some code and I want to change the search parameters to an array so I can find "shipped" and "partial - shipped" but not too sure how. Can someone please take a look and give me some guidance?

Sub DeleteRows()
    
    Dim c As Range
    Dim SrchRng

    Set SrchRng = ActiveSheet.Range("D1", ActiveSheet.Range("D65536").End(xlUp))
    Do
        Set c = SrchRng.Find("shipped", LookIn:=xlValues)
        If Not c Is Nothing Then c.EntireRow.Delete
    Loop While Not c Is Nothing
    
End Sub

 

[DanteAmor]

Try this

Sub DeleteRows()
    Dim c As Range
    Dim SrchRng

    Set SrchRng = ActiveSheet.Range("D1", ActiveSheet.Range("D65536").End(xlUp))
    Do
        Set c = SrchRng.Find("shipped", , xlValues, xlPart)
        If Not c Is Nothing Then c.EntireRow.Delete
    Loop While Not c Is Nothing
End Sub

 

[mumps]

This macro assumes you have headers in row 1 and your data starts in row 2 with no blank rows.

Sub DeleteRows()
    With Cells(1, 1).CurrentRegion
        .AutoFilter Field:=4, Criteria1:="=partial - shipped", Operator:=xlOr, Criteria2:="=shipped"
        ActiveSheet.AutoFilter.Range.Offset(1, 0).EntireRow.Delete
    End With
    Range("A1").AutoFilter
End Sub

 

[Enzo_Matrix]

This macro assumes you have headers in row 1 and your data starts in row 2 with no blank rows.

Sub DeleteRows()
    With Cells(1, 1).CurrentRegion
        .AutoFilter Field:=4, Criteria1:="=partial - shipped", Operator:=xlOr, Criteria2:="=shipped"
        ActiveSheet.AutoFilter.Range.Offset(1, 0).EntireRow.Delete
    End With
    Range("A1").AutoFilter
End Sub

MUMPS! you've helped me twice now with the same project in as many days. my hero! *swoon*

 

[DanteAmor]

There are other ways to delete rows, In addition to fixing your macro.
Here is another approach to delete lines :

Sub DeleteRows_2()
  With ActiveSheet
      .Columns("D").Replace what:="*shipped*", replacement:="#N/A", Lookat:=xlWhole
      On Error Resume Next
      .UsedRange.SpecialCells(xlCellTypeConstants, xlErrors).EntireRow.Delete
  End With
End Sub

 

[mumps]

Glad to help.