Select multiple specific pages on Userform Multipage

[CheekyDevil2386]

Hi there!

Is there a simple way to run the below code on multiple, specific pages within a userform multipage?

I want this code to run on pages 1 and 2, but not any others (I have controls on other pages I can't have cleared, so using "userform1.multipage1.controls" isn't an option for me)

Dim oneControl As Object
For Each oneControl In MultiPage1.Pages(2).Controls
 Select Case TypeName(oneControl)
 Case "TextBox"
 oneControl.Text = vbNullString
 Case "CheckBox"
 oneControl.Value = False
 End Select
Next oneControl

Ideally, i would like to have something like:

For Each oneControl In MultiPage1.Pages(1+2).Controls

or similar?

Thank you for any assistance anyone can provide

 

[Domenic]

Try the following code...

    Dim pageNumbers As Variant
    Dim pageNumber As Variant
    Dim oneControl As Object
    
    pageNumbers = Array(1, 2)
    
    For Each pageNumber In pageNumbers
        For Each oneControl In MultiPage1.Pages(pageNumber).Controls
            Select Case TypeName(oneControl)
                Case "TextBox"
                    oneControl.Text = vbNullString
                Case "CheckBox"
                    oneControl.Value = False
            End Select
        Next oneControl
    Next pageNumber

Hope this helps!

 

[Norie]

You could create a function that takes a page as an argument.

Function ClearPage(pg As MsForms.Page)
Dim ctl As MsForms.Control

    For Each ctl In pg.Controls
        Select Case TypeName(ctl)
            Case "TextBox"
                ctl.Text = vbNullString
                ClearPage = ClearPage + 1
            Case "CheckBox"
                ctl.Value = False
                ClearPage = ClearPage + 1
        End Select
    Next ctl

End Function

That could then be called like this.

    ClearPage Me.MultiPage1.Pages(0)
    ClearPage Me.MultiPage1.Pages(1)

 

[CheekyDevil2386]

Thank you both very much for the answers above! Much appreciated and utmost apologies for the delay in my reply.

Haven't yet managed to get it into the project yet but looking at the two they'll be perfect for a few other ideas I have too

Really appreciate the help guys, thank you for the time you gave

 

[Domenic]

That's great, we're glad to help, cheers!