Select Range, Change Each Row Color, Macro

[teksp0rt]

I am fairly new to writing macros in VBA.

What I would like to do is select a range of rows and column with my mouse...

1. For example, I would select the range B20:Z50
2. Then, I would like to hit a macro button..
3. Every other row - the color of the row will change to light grey hex: #F2F2F2

Anyone have advice on how to get me started?

 

[Norie]

This might help.

Sub HighlightRows()
Dim rng As Range
Dim rngRow As Range

    Set rng = Selection
    
    For Each rngRow In rng.Rows
        If rngRow.Row Mod 2 = 1 Then
            rngRow.Interior.Color = &HF2F2F2
        Else
            rngRow.Interior.Color = xlNone
        End If
    Next rngRow
    
End Sub

 

[Fluff]

How about

Sub teksport()
   Dim Cl As Range
   
   For Each Cl In Selection.Rows
      If Cl.Row Mod 2 = 0 Then Cl.Interior.Color = RGB(242, 242, 242)
   Next Cl
End Sub

 

[Joe4]

Try this code:

Sub MyCFMacro()

    With Selection
        .FormatConditions.Add Type:=xlExpression, Formula1:="=MOD(ROW(),2)=1"
        .FormatConditions(.FormatConditions.Count).SetFirstPriority
        With .FormatConditions(1).Interior
            .PatternColorIndex = xlAutomatic
            .ThemeColor = xlThemeColorDark1
            .TintAndShade = -0.14996795556505
        End With
        .FormatConditions(1).StopIfTrue = False
    End With
    
End Sub

Change the color to your liking (you can get the code you want ny recording yourself applying it, and then taking that number and replacing the one in my code above).

 

[teksp0rt]

that was fast. thank you all

 

[Fluff]

Glad we could help & thanks for the feedback.