Select Worksheets in Macro

[tigerfan81]

I'm looking for some code (user input box) to enable the user to select worksheets at a certain point in the macro. I have multiple workbooks and the sheets that need modification varies from workbook to workbook.

Thanks

 

[AlphaFrog]

Sub Prompt_to_Select_Sheet()

    Dim strSheet As String, ws As Worksheet
    
Retry:
    strSheet = Application.InputBox("Enter the sheet name to select.", "Select Sheet", Type:=2)
    If strSheet = "False" Then Exit Sub     'User canceled
    
    On Error Resume Next
        Set ws = Sheets(strSheet)
    On Error GoTo 0
    
    If ws Is Nothing Then
        If MsgBox("Can't select the sheet named " & strSheet & vbCr & vbCr & _
                  "Try again?", vbExclamation + vbYesNo, "Sheet Not Found") _
                  = vbYes Then GoTo Retry
    Else
        ws.Select
    End If
    
End Sub

 

[tigerfan81]

Thanks a lot for your help.....

 

[daverunt]

Here's some code for an input box so you have only to enter a number.

Sub SheetSelection()
    Dim v(1 To 100) As Long
    Dim j As Long
    Dim i As Long
 
'Count the sheets
    WorkSheetList = ActiveWorkbook.Sheets.Count
 
'Create Sheetlist
 
    j = 0
    For i = 1 To WorkSheetList
    j = j + 1
    v(j) = i
    SheetList = SheetList & j & " - " & ActiveWorkbook.Sheets(i).Name & " " & vbCr
    Next i
 
'Show InputBox with list of sheets
   WorkSheetList = InputBox("Enter sheet number required." & vbCr & vbCr & SheetList)
 
'Sheet opens at  number input
   Sheets(v(WorkSheetList)).Select
End Sub