Simple copy/paste with worksheet variables

[jardenp]

My copy/paste in the "problem line" below is returning a run time error 1004 Method 'Range' of object '_ Worksheet' failed.

What am I doing wrong? I know that the If statement is true for the first time at row 3045 and that the msgboxes return the correct sheet names when I have those lines uncommented.

Thanks!

    Dim OWS As Worksheet
        Set OWS = ActiveWorkbook.ActiveSheet
        'MsgBox OWS.Name
    RowS("1:1").copy
    Sheets.Add After:=Sheets(Sheets.Count)
    RowS("1:1").Select
    ActiveSheet.Paste
    ActiveSheet.Name = "AR Transaction Lines"
    Dim ARTL As Worksheet
        Set ARTL = ActiveWorkbook.ActiveSheet
        'MsgBox ARTL.Name
       
    Dim r As Integer 'row counter
    Dim s As Integer '"Split" column
        s = 11
    Dim addrow As Integer 'row counter for adding lines on AR sheet
        addrow = 2
           
    For r = 2 To 3047 'OWS.Range("B1000000").End(xlUp).row

        If OWS.Cells(r, s) = "1120 · Accounts Receivable" Then
            OWS.Range(Cells(r, 1), Cells(r, 13)).copy ARTL.Range(Cells(addrow, 1), Cells(addrow, 13)) '****Problem line****
            addrow = addrow + 1
        End If
       
    Next r

 

[Joe4]

Do you have any merged cells, protected cells, or hidden rows on either sheet?

 

[jardenp]

Joe, I don't think so. I don't see any. When I select all cells the merge cells button doesn't highlight. I tried unhide for all columns and rows on the original and ran the code and got the same result.

 

[Joe4]

If you hit debug when you get that error, try going to that line of code and hovering over the "addrow", "r", and "s" variables to see what they all are.
Then, go to your datasheet, and check out that row and make sure that there isn't any issue with it (errors, other odd occurrences, etc).

 

[jardenp]

addrow = 2, r = 3045, s = 11 as expected.

 

[Joe4]

Try this:

    Dim OWS As Worksheet
        Set OWS = ActiveWorkbook.ActiveSheet

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "AR Transaction Lines"
    
    Dim ARTL As Worksheet
        Set ARTL = ActiveWorkbook.ActiveSheet
    
    OWS.Rows(1).Copy ARTL.Range("A1")

    Dim r As Integer 'row counter
    Dim s As Integer '"Split" column
        s = 11
    Dim addrow As Integer 'row counter for adding lines on AR sheet
        addrow = 2
           
    For r = 2 To 3047 'OWS.Range("B1000000").End(xlUp).row

        If OWS.Cells(r, s) = "1120 · Accounts Receivable" Then
            OWS.Range(Cells(r, 1), Cells(r, 13)).Copy ARTL.Cells(addrow, 1)
            addrow = addrow + 1
        End If
       
    Next r

Note you could also avoid the loop by using Filters instead.
See: Dynamically Filter Data from One Worksheet to Another in Microsoft Excel 2010

 

[jardenp]

I still get the same error on the same line. Any idea why

OWS.Rows(1).Copy ARTL.Range("A1")

works but not

OWS.Range(Cells(r, 1), Cells(r, 13)).Copy ARTL.Cells(addrow, 1)

?

 

[Joe4]

It works for me. What happens if you qualify each instance of "Cells"?, i.e.

OWS.Range(OWS.Cells(r, 1), OWS.Cells(r, 13)).Copy ARTL.Cells(addrow, 1)

If that still does not work, try manually copying the first thirteen columns of a row on your OWS sheet and pasting it to your other sheet?
Does that work? Can you do it manually?

By the way, please update your profile so that we can see which version of Excel you are working with.

 

[jardenp]

That worked! Thanks. With much gratitude. Manually copying isn't an option since the script will run on sheets with thousands of rows.

 

[Joe4]

That worked! Thanks. With much gratitude.

You are welcome.

Manually copying isn't an option since the script will run on sheets with thousands of rows.

No, I was not suggesting that as a solution. I just wanted you to test it to see if there was some issue preventing you from copy/pasting.
It is a debugging technique.