Simple Question

[bfraser]

I want to bring up a message (A Reason Code is Required on all SSL, SPN & SFL Time Codes) when a series of cells (e13 to e60) contain any one of the following three codes, SSL, SPN or SFL. Can someone tell me what is wrong with my formula below?
Thank you.

=IF(E13:E60="SSL", "SPN", "SFL", "A Reason Code is Required on all SSL, SPN & SFL Time Codes","")

 

[crook_101]

Hi,

Try:

=IF(COUNTIF(E13:E60,"*SSL*"),"A Reason Code is Required on all SSL, SPN & SFL Time Codes",IF(COUNTIF(E13:E60,"*SPN*"),"A Reason Code is Required on all SSL, SPN & SFL Time Codes",IF(COUNTIF(E13:E60,"*SFL*"),"A Reason Code is Required on all SSL, SPN & SFL Time Codes","")))

HTH
ian

 

[AMAS]

Hi,

This works for me with an Array entered as ENTER+SHIFT+CTRL

{=IF(OR(E13:E60="SSL",E13:E60="SPN",E13:E60="SFL"),"A Reason Code is Required on all SSL, SPN & SFL Time Codes","")}

Others may have simpler approaches.

Good luck.

AMAS

 

[snoopyhr]

try :
=IF(OR(E13:E60="SSL",E13:E60= "SPN",E13:E60= "SFL"),"A Reason Code is Required on all SSL, SPN & SFL Time Codes","")

confirm with Ctrl Shift Enter, this an array formula

 

[ZVI]

Would be also:
=IF(SUMPRODUCT(-(E13:E60={"SSL","SPN","SFL"})),"A Reason Code is Required on all SSL, SPN & SFL Time Codes","")

But seems that inverse result is more correct:
=IF(SUMPRODUCT(-(E13:E60={"SSL","SPN","SFL"})),"","A Reason Code is Required on all SSL, SPN & SFL Time Codes")