Skip Print Specific Sheet of group, IF Specific Cell Value is blank in that sheet.

[Waleed_wwn]

I have the below code to Print Some Sheets by using array code.
How to Skip Print Specific Sheet of this group, IF Specific Cell Value (D4) is blank in that sheet.

Sub Print_Some_Sheet()

Worksheets(Array("Sheet1", "Sheet2", "Sheet3", "Sheet4", "Sheet4")).PrintOut , collate:=True

End Sub

 

[severynm]

Hello and welcome!

To accomplish this we need to examine each worksheet individually before printing out. Use a loop to look through each worksheet, and you want to print only if Not Isempty(ws.Range("D4").Value) (i.e. if D4 in the current worksheet is not empty or "blank").

Private Sub PrintSomeSheets()
    Dim idx As Integer
    Dim ws As Worksheet
    
    For Each ws In ThisWorkbook.Worksheets
        If Not IsEmpty(ws.Range("D4").Value) Then
            ws.PrintOut
        End If
    Next
End Sub

 

[Waleed_wwn]

But , your code will print all sheets in workbook ( except if D4 is blank) . My question is about selection of sheets in same workbook.
Any way thanks, I found this code that works ok

 [/I]
Sub Print_Some_Sheet()
Dim sh As Worksheet
Dim strName As Worksheet
Dim arrSheets As Variant
Dim arrSheetsToPrint As Variant
Dim cnt As Long
Dim idx As Long

    arrSheets = Array("Sheet1", "Sheet2", "Sheet3", "Sheet4")

    ReDim arrSheetsToPrint(LBound(arrSheets) To UBound(arrSheets))
   
    For idx = LBound(arrSheets) To UBound(arrSheets)
        Set sh = Sheets(arrSheets(idx))
        If sh.Range("D4").Value <> "" Then
            arrSheetsToPrint(cnt) = arrSheets(idx)
            cnt = cnt + 1
        End If
    Next idx
    
    If cnt > 0 Then
        ReDim Preserve arrSheetsToPrint(cnt - 1)
        Worksheets(arrSheetsToPrint).PrintOut , collate:=True
    End If
    
End Sub
[I]

 

[Waleed_wwn]

Change sheets names and Range ( Cell ) as required