skipping cells

[khoover12]

I am working on an inventory log sheet; I need help with a code that when after entering value/text into cell A5(column A) that the cursor will move to cell C5(column C) and after a value/text is entered into C5 the cursor moves to cell E5(column E). Can anyone help me create this code or point me in the right direction?

 

[gallen]

Private Sub Worksheet_Change(ByVal Target As Range)
    Select Case Target.Column
        Case 1 'column a
            Cells(Target.Row, 3).Select 'move to Col c
        Case 3 ' COlumn C
            Cells(Target.Row, 5).Select ' move t
        Case 5 ' column E
            'Whatever you need to do when user has exited last column
        Case Else
    End Select
End Sub

 

[rollis13]

Hi to all.
I prefer this approach. The macro needs to be pasted in the sheet's module becaused it is triggered by event Worksheet_Change.

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
    Select Case Target.Address()
        Case "$A$5"
            Range("$C$5").Select
        Case "$C$5"
            Range("$E$5").Select
        Case "$E$5"
            Range("$A$5").Select
    End Select
End Sub

 

[Rick Rothstein]

Since you said you want this to happen after entering a value, I think you should use the Change event to do it. I assume your specifying cells A5 and C5 was for example purposes only and that you want this movement from column to column to occur for entries into any cell in Columns A or C.

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.CountLarge = 1 Then
    If Target.Column = 1 Or Target.Column = 3 Then Target.Offset(, 2).Select
  End If
End Sub

HOW TO INSTALL Event Code
------------------------------------
If you are new to event code procedures, they are easy to install. To install it, right-click the name tab at the bottom of the worksheet that is to have the functionality to be provided by the event code and select "View Code" from the popup menu that appears. This will open up the code window for that worksheet. Copy/Paste the event code into that code window. That's it... the code will now operate automatically when its particular event procedure is raised by an action you take on the worksheet itself. Note... if you are using XL2007 or above, make sure you save your file as an "Excel Macro-Enabled Workbook (*.xlsm) and answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.