Sort multiple tables

[Peterfc2]

Multi table sort.

Sub Button1_Click()

    Range("A2:I21").Select
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("I3:I21") _
        , SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("H3:H21") _
        , SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
    ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("F3:F21") _
        , SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("Sheet1").Sort
        .SetRange Range("A2:I21")
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    Range("M10").Select
End Sub

I have 6 tables plus that need sorting as above in the recorded macro.
Each table is the same size
a2:i21
a25:i44
a48:i67 etc.
23 row between tables. How can vba sort all the tables please?

 

[Fluff]

Do your tables ahve headers & if so are they in rows 2, 25 & 48?

 

[Eric W]

Try:

Sub Button1_Click()
Dim i As Long

    For i = 0 To 5
    
        With ActiveWorkbook.Worksheets("Sheet1").Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("I3").Offset(i * 23), Order:=xlDescending
            .SortFields.Add Key:=Range("H3").Offset(i * 23), Order:=xlDescending
            .SortFields.Add Key:=Range("F3").Offset(i * 23), Order:=xlDescending
            .SetRange Range("A2:I21").Offset(i * 23)
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .Apply
        End With
    
    Next i
    
End Sub

 

[Peterfc2]

Excellent! Works a dream

 

[Eric W]

Glad we could help! Thanks for the update.