Sorting Jagged Arrays

[flyfisher65]

language: VBA
I am trying to create a vba macro that will sort a jagged array (an array containing other arrays) by the elements of the first array. I want to keep the move the rest of the data in the "smaller" arrays with the column being sorted. This process is looped several times. Im not sure exactly how to describe it, but I tried to visualize it in the example below. I am not familiar with sorting code and would like some help on what to do. I tried putting it into an new worksheet and sorting it in excell, but some of the outputs (there are several because of the loop) were increasing L-R while others were deceasing. I want them to increase but am not sure how to do this.
Example (each character represents and element in the jagged array () encloses one of the "smaller" arrays)
(1AAAAA)
(4DDDDD)
(3CCCCC)
(2BBBBB)
would sort to
(1AAAAA)
(2BBBBB)
(3CCCCC)
(4DDDDD)
problem:
some outputs end up like this
(4DDDDD)
(3CCCCC)
(2BBBBB)
(1AAAAA)
thanks in advance
-Lewis

 

[mirabeau]

hi Lewis,

do you mean something like this?

Sub sortof()
Range("A1").CurrentRegion.sort Range("A1"), xlAscending, Header:=xlNo
End Sub

 

[AlphaFrog]

Sub Array_Sort()
    
    Dim v As Variant, vTemp As Variant
    Dim i As Long, j As Long
    Dim col As Long
    
    v = Array(Array(1, "A", "A", "A", "A", "A"), _
              Array(4, "D", "D", "D", "D", "D"), _
              Array(3, "C", "C", "C", "C", "C"), _
              Array(2, "B", "B", "B", "B", "B"))
    'Sort
    col = 0 'Sort on column 0
    For i = LBound(v, 1) To UBound(v, 1) - 1
        For j = LBound(v, 1) To UBound(v, 1) - 1
            If v(j)(col) > v(j + 1)(col) Then
               vTemp = v(j)
               v(j) = v(j + 1)
               v(j + 1) = vTemp
            End If
    Next j, i
    
End Sub

 

[flyfisher65]

yes, the "xlAscending" option was what I was looking for. I realize now what a simple thing it was. Thanks for the help