Sorting Worksheet for check deposits - advanced

[HomePro]

So I cant figure out how to do this.

I want to search thru a worksheet in column "A" for any instance of the entry "Returned". If found then get the data from columns "C" [name] and "D" [amount].
Now search thru the entire worksheet for any row that matches the data from columns C&D and copy them to another worksheet.
The result should be worksheet with a complete list of returned checks and any other instance from that client for the same amount [this would be the original deposit and any redeposit.]

I cannot get my head around how to do this.
Can anyone help?
Tks.

 

[igold]

It would helpful if you showed us a sample of what your data looks like (real or fictitious).

 

[JamesCanale]

This kind of works in excel 2019. But if you get 365, there is a one-formula solution.

MrExcelPlayground5.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1						Excel 2019					Excel 365
2	Status	Date	Name	Amount				Date of Returned Check	Date of Ok check		Status	Date	Name	Amount
3	Ok	1-Nov	Fred	99		4	Mary100	11/4/2021	11/9/2021		Ok	11/6/2021	Fred	10
4	Ok	2-Nov	George	98		11	James150	11/11/2021	11/5/2021		Returned	11/12/2021	Fred	10
5	Ok	3-Nov	Harry	97		12	Fred10	11/12/2021	11/6/2021		Ok	11/19/2021	George	200
6	Returned	4-Nov	Mary	100		18	Harry300	11/18/2021			Returned	11/20/2021	George	200
7	Ok	5-Nov	James	150		20	George200	11/20/2021	11/19/2021		Returned	11/18/2021	Harry	300
8	Ok	6-Nov	Fred	10							Ok	11/5/2021	James	150
9	Ok	7-Nov	George	20							Returned	11/11/2021	James	150
10	Ok	8-Nov	Harry	30							Returned	11/4/2021	Mary	100
11	Ok	9-Nov	Mary	100							Ok	11/9/2021	Mary	100
12	Ok	10-Nov	Mary	50							Ok	11/24/2021	Mary	100
13	Returned	11-Nov	James	150
14	Returned	12-Nov	Fred	10
15	Ok	13-Nov	George	55
16	Ok	14-Nov	James	45
17	Ok	15-Nov	Fred	54
18	Ok	16-Nov	George	42
19	Ok	17-Nov	Mary	35
20	Returned	18-Nov	Harry	300
21	Ok	19-Nov	George	200
22	Returned	20-Nov	George	200
23	Ok	21-Nov	Fred	104
24	Ok	22-Nov	James	70
25	Ok	23-Nov	James	60
26	Ok	24-Nov	Mary	100
27	Ok	25-Nov	Fred	40
Sheet9

Cell Formulas
Range	Formula
F3	F3	=MATCH("Returned",A3:A27,0)
G3:G22	G3	=IFERROR(INDEX($C$3:$D$27,F3,1)&INDEX($C$3:$D$27,F3,2),"")
H3:H22	H3	=IFERROR(INDEX($B$3:$B$27,MATCH("Returned"&G3,$A$3:$A$27&$C$3:$C$27&$D$3:$D$27,0)),"")
I3:I22	I3	=IFERROR(INDEX($B$3:$B$27,MATCH("Ok"&G3,$A$3:$A$27&$C$3:$C$27&$D$3:$D$27,0)),"")
F4:F22	F4	=IFERROR(MATCH("Returned",OFFSET($A$3,F3,0,ROWS($A$3:$A$27)-F3),0)+F3,"")
K3:N12	K3	=SORT(FILTER(A3:D27,NOT(ISNA(MATCH(C3:C27&D3:D27,INDEX(FILTER(A3:D27,A3:A27="Returned"),,3)&INDEX(FILTER(A3:D27,A3:A27="Returned"),,4),0)))),3)
Dynamic array formulas.