Split Panes Vertical Scroll Bar

[ChristineJ]

I have used split panes to show two copies of my screen side by side/left and right. There are already two horizontal scroll bars on the bottom - one on each pane. There is only one vertical scroll bar on the right side of the right pane. Two questions:

1. Can a VERTICAL scroll bar be added to the right side the left pane so that each pane can independently be scrolled up and down without the other pane scrolling simultaneously?

1. Is there a way to remove these HORIZONTAL scroll bars on the bottom?

Thanks! (My first post...)

 

[pgc01]

Hi ChristineJ
Welcome to the board

1 -

Instead of using the panes, display another window for the workbook

- menu Window->New Window (in xl2007 View->New Window)
- menu Window->Arrange->Vertical (in xl2007 View->Arrange All->Vertical)

2 -

You can set it in the excel options, Tools->Options->View (xl2007: Excel Options->Advanced->Workbook->Display Options for this Workbook


P. S. Next time please post your excel version.

 

[ChristineJ]

Thank you! I am currently working in the 2003 version. Although I have 2007 as well, I'm a college professor and many of my students seem to have 2003 on their computers. So I'll stick with that for now.

I tried your suggestion, and it achieves the effect I want. The only issue is that it splits the screens on all of the pages in the workbook, and I only want to do so on selected pages. Any workaround to that?

CJ

 

[pgc01]

No, but the windows are independent.

When you display more than one window you'll notice that each one has its own set of Minimize-Restore-Maximize buttons.

If you want to see another worksheet in just one window just select it in any of the windows and ckick on the maximize button of that window. Then when you get back to the worksheet you want to see splitted, click on the restore button (the windows buttons if the window is not split are located just below the ones of the application window).

Does this solve your problem?

 

[ChristineJ]

This is very close to getting at what I need, but I can't rely on the users/students to know how and when to minimize and restore the screens properly. My goal was to get each page set up exactly the way they will need it and prevent them from changing anything format-wise.

The issue is that only some of the pages require the split screen feature.

CJ

 

[pgc01]

I'm just leaving but maybe this will help.

You can make the process automatic, but that requires vba.

Ex. right-click on a worksheets tab and choose "view code". You'll be taken to the worksheet's code module.

Paste:

Private Sub Worksheet_Activate()
    ActiveWindow.NewWindow
    Windows.Arrange ArrangeStyle:=xlVertical
End Sub
 
Private Sub Worksheet_Deactivate()
Dim ws As Worksheet
 
    Set ws = ActiveSheet
    ActiveWindow.Close
    ActiveWindow.WindowState = xlMaximized
    Application.EnableEvents = False
    ws.Activate
    Application.EnableEvents = True
End Sub

Now get back to the workbook. Each time you activate this window the screen splits. When you activate another worksheet, one of the workbook windows is closed and the split is removed.

This is just a simple example to get you started.
HTH

 

[ChristineJ]

Awesome! Works like a charm! Thanks for taking the time to help me out.

I can write calculation formulas all day long, but I now have a total of two modules in my collection. However, BOTH (including yours) are EXACTLY what I need to do what I want. I guess I have to learn how to do this! Hard thing for a teacher to admit.

Again - THANKS! CJ

 

[ChristineJ]

I have been using the code pgc01 provided for splitting windows vertically. It there a way to split a window into THREE panes in a t-bone effect? The top 25% of the screen would extend all the way across the screen; the bottom 75% of the screen would be split in two.

Thanks!

 

[pgc01]

Hi CJ

Instead of using one of the default arrange styles we can play around with the size and location of the windows. Try replacing the old code with:

Option Explicit
 
Private Sub Worksheet_Activate()
Dim wd As Double, ht As Double
    
    wd = Application.UsableWidth
    ht = Application.UsableHeight
    
    With ActiveWindow
        .WindowState = xlNormal
        .Left = 0
        .Top = 0
        .Width = wd
        .Height = ht / 4
    End With
    
    With ActiveWindow.NewWindow
        .Left = 0
        .Top = ht / 4
        .Width = wd / 2
        .Height = ht * 3 / 4
    End With
    
    With ActiveWindow.NewWindow
        .Left = wd / 2
        .Top = ht / 4
        .Width = wd / 2
        .Height = ht * 3 / 4
    End With
    
End Sub
 
Private Sub Worksheet_Deactivate()
Dim ws As Worksheet
 
    Set ws = ActiveSheet
    ActiveWindow.Close
    ActiveWindow.Close
    Application.EnableEvents = False
    ws.Activate
    Application.EnableEvents = True
    ActiveWindow.WindowState = xlMaximized
End Sub

 

[ChristineJ]

Perfect! Thank you so much for providing the code. Not only does it solve my immediate need, but I also learn a lot about VBA from the code. Thanks again, Chris