Split the prize amounts for ties?

[Douglas Edward]

How do I create a formula to split the prize amounts for ties? (It's for a golf league)

Player Score Rank Prize Rank Prize In this example the prize payout should be…
A 70 1 ? 1 100 95
B 70 1 ? 2 90 95
C 71 3 ? 3 80 70
E 71 3 ? 5 60 70
F 72 6 ? 6 50 30
G 72 6 ? 7 40 30
H 72 6 ? 8 30 30
I 72 6 ? 9 20 30
J 72 6 ? 10 10 30

 

[fhqwgads]

like this?

Player	Score	Rank	Prize	Rank	Prize
A	70	1	95	1	100
B	70	1	95	2	90
C	71	3	70	3	80
E	71	3	70	5	60
F	72	6	30	6	50
G	72	6	30	7	40
H	72	6	30	8	30
I	72	6	30	9	20
J	72	6	30	10	10

formula in D2 the cell below prize

=SUMIF($C$2:$C$10,C2,$F$2:$F$10)/COUNTIF($C$2:$C$10,C2)

just replace $C$10 and $F$10 with the last cell in your list. hope that works

 

[Douglas Edward]

That works perfectly! Thank you fhqwgads!

Now I just wish I understood how it works. ha

Any chance you could give a explanation?

 

[Douglas Edward]

I spoke too soon.

It works perfectly if you keep the rank column sorted in ascending order.

But If the rank column is in a random order, the prize column stays in descending order.

 

[Marcelo Branco]

Maybe something like this

	A​	B​	C​	D​	E​	F​	G​
1​	Player​	Score​	Rank​	Prize​		Rank​	Prize​
2​	A​	72​	8​	10​		1​	100​
3​	B​	70​	1​	90​		2​	90​
4​	C​	71​	4​	45​		3​	80​
5​	E​	71​	4​	45​		4​	60​
6​	F​	73​	11​	0​		5​	50​
7​	G​	71​	4​	45​		6​	40​
8​	H​	72​	8​	10​		7​	30​
9​	I​	72​	8​	10​		8​	20​
10​	J​	73​	11​	0​		9​	10​
11​	K​	70​	1​	90​
12​	L​	71​	4​	45​
13​	M​	70​	1​	90​
14​
15​			Total​	480​		Total​	480​

Formula in C2 copied down (Rank)
=COUNTIF(B$2:B$13,"<"&B2)+1

Formula in D2 copied down
=IF(C2>9,0,SUM(OFFSET(INDEX(G$2:G$10,MATCH(C2,$F$2:$F$10,0)),,,MIN(9-MATCH(C2,F$2:F$10,0)+1,COUNTIF(C$2:C$13,C2))))/COUNTIF(C$2:C$13,C2))

Just to check...
Formula in D15
=SUM(D2:D13)

Formula in G15
=SUM(G2:G10)

Hope this helps

M.

 

[fhqwgads]

basically to split between ties we need to find the average of the prize money, which is the total prize money divided by the number of people with the same score

=SUMIF($C$2:$C$10,C2,$F$2:$F$10)/COUNTIF($C$2:$C$10,C2)

to find the total prize money of people with the same score we use SUMIF

SUMIF adds numbers together based on various criteria
SUMIF(range of cells your are checking, criteria you are checking for, range of numbers to sum)
the range we are looking at is all the possible places in $C$2 to the bottom (now that i think about it, you might be able to just use the whole of column C as a reference instead of specifying C2 to whatever if you want to simplify the code a bit). the criteria we are looking for is the place that specific player got in C2. and the range of numbers sum adds the numbers that fulfill the criteria

basically it looks at what place the player got and adds all the prize money amounts that have the same place

COUNTIF gives us the number of players with the same place

COUNTIF(range you're looking in, what you're looking for)

this gives you a count of all the occurrences of the value you're looking for, in this case the player's place, in the range

sorry it's not the best explanation. i'm not great with words. the office support site have better explanations and examples

https://support.office.com/en-us/article/sumif-function-169b8c99-c05c-4483-a712-1697a653039b
https://support.office.com/en-us/article/COUNTIF-function-E0DE10C6-F885-4E71-ABB4-1F464816DF34

 

[fhqwgads]

ah sorry my solution didnt work out. hopefully other people can help

 

[kvsrinivasamurthy]

Player	score	rank	prize	rank	prize
A	70	1	95	1	100
B	72	6	30	2	90
C	72	6	30	3	80
E	71	3	40	5	60
F	72	6	30	6	50
G	70	1	95	7	40
H	71	3	40	8	30
I	72	6	30	9	20
J	72	6	30	10	10

<colgroup><col width="64" span="6" style="width:48pt"> </colgroup><tbody>
</tbody>

For random ranks
Formula in C2 then dragdown

=SUMPRODUCT(($F$2:$F$10)*($E$2:$E$10>=C2)*($E$2:$E$10<(C2+COUNTIF($C$2:$C$10,C2))))/COUNTIF($C$2:$C$10,C2)

 

[kvsrinivasamurthy]

Refering to post#8
Rank number 4 is missing. If 4 is inserted in E column formula works ok.

 

[Marcelo Branco]

A simpler formula

	A​	B​	C​	D​	E​	F​	G​
1​	Player​	Score​	Rank​	Prize​		Rank​	Prize​
2​	A​	72​	8​	10​		1​	100​
3​	B​	70​	1​	90​		2​	90​
4​	C​	71​	4​	45​		3​	80​
5​	E​	71​	4​	45​		4​	60​
6​	F​	73​	11​	0​		5​	50​
7​	G​	71​	4​	45​		6​	40​
8​	H​	72​	8​	10​		7​	30​
9​	I​	72​	8​	10​		8​	20​
10​	J​	73​	11​	0​		9​	10​
11​	K​	70​	1​	90​
12​	L​	71​	4​	45​
13​	M​	70​	1​	90​
14​
15​			Total​	480​		Total​	480​

Formula in C2 copied down (Rank)
=COUNTIF(B$2:B$13,"<"&B2)+1

Formula in D2 copied down
=SUMIFS(G$2:G$10,F$2:F$10,">="&C2,$F$2:$F$10,"<="&C2+COUNTIF(C$2:C$13,C2)-1)/COUNTIF(C$2:C$13,C2)

M.