Spreadsheet Comparison Help

[NeoSez]

Noob here.
I have tried so many different ways to compare and find the changes of Columns L&M based on Q.
Tried Access but it only exports two columns and I have no idea what it is referencing OR it extracts all rows. I don't really know my way around ACCESS.
Tried Conditional formatting but it didn't work.
Tried everything.

What I need:

• Find what rows have changes in columns L&M from the daily UPDATES sheet, compared to the current running DATA sheet and highlight.
• Highlight / add the changes to DATA sheet col L&M from UPDATES sheet col L&M
• Any new rows found in the UPDATES sheet, also add to the DATA sheet
• Col Q is the unique ID #.

What is the easiest method please.
Greatly appreciate your help.

A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
DATE	Pet	Location	FIRST_NAME	LAST_NAME	EMAIL	TELEPHONE	ADDRESS	CITY	PROVINCE	POSTAL_CODE	CALLED	VISITED	Status	Vet	Desc	Unique ID
dd/mm/yyyy	Sheep										yes	no				123
dd/mm/yyyy	Dog										no	no				456
dd/mm/yyyy	Rabbit										yes	yes				789
DATA TAB

A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
DATE	Pet	Location	FIRST_NAME	LAST_NAME	EMAIL	TELEPHONE	ADDRESS	CITY	PROVINCE	POSTAL_CODE	CALLED	VISITED	Status	Vet	Desc	Unique ID
dd/mm/yyyy	Sheep										yes	yes				123
dd/mm/yyyy	Dog										no	yes				456
dd/mm/yyyy	Rabbit										yes	yes				789
dd/mm/yyyy	Cat										no	no				666
dd/mm/yyyy	Bird										no	no				777
UPDATES

 

[Fluff]

How about

Sub NeoSez()
   Dim Cl As Range
   Dim Dic As Object
   Dim UsdRws As Long
   
   Set Dic = CreateObject("scripting.dictionary")
   With Sheets("Data")
      UsdRws = .Range("Q" & Rows.Count).End(xlUp).Row
      For Each Cl In .Range("Q2:Q" & UsdRws)
         If Not Dic.Exists(Cl.Value) Then Dic.Add Cl.Value, Array(Cl, Cl.Offset(, -5).Value, Cl.Offset(, -4).Value)
      Next Cl
   End With
   With Sheets("Updates")
      For Each Cl In .Range("Q2", .Range("Q" & Rows.Count).End(xlUp))
         If Dic.Exists(Cl.Value) Then
            If Cl.Offset(, -5).Value <> Dic(Cl.Value)(1) Then
               Dic(Cl.Value)(0).Offset(, -5).Value = Cl.Offset(, -5).Value
               Dic(Cl.Value)(0).Offset(, -5).Interior.Color = vbYellow
            End If
            If Cl.Offset(, -4).Value <> Dic(Cl.Value)(2) Then
               Dic(Cl.Value)(0).Offset(, -4).Value = Cl.Offset(, -4).Value
               Dic(Cl.Value)(0).Offset(, -4).Interior.Color = vbYellow
            End If
         Else
            Cl.EntireRow.Copy Sheets("Data").Range("A" & UsdRws + 1)
            Sheets("Data").Range("A" & UsdRws + 1).Resize(, 17).Interior.Color = vbYellow
            UsdRws = UsdRws + 1
         End If
      Next Cl
   End With
End Sub

 

[NeoSez]

How about

Sub NeoSez()
   Dim Cl As Range
   Dim Dic As Object
   Dim UsdRws As Long
  
   Set Dic = CreateObject("scripting.dictionary")
   With Sheets("Data")
      UsdRws = .Range("Q" & Rows.Count).End(xlUp).Row
      For Each Cl In .Range("Q2:Q" & UsdRws)
         If Not Dic.Exists(Cl.Value) Then Dic.Add Cl.Value, Array(Cl, Cl.Offset(, -5).Value, Cl.Offset(, -4).Value)
      Next Cl
   End With
   With Sheets("Updates")
      For Each Cl In .Range("Q2", .Range("Q" & Rows.Count).End(xlUp))
         If Dic.Exists(Cl.Value) Then
            If Cl.Offset(, -5).Value <> Dic(Cl.Value)(1) Then
               Dic(Cl.Value)(0).Offset(, -5).Value = Cl.Offset(, -5).Value
               Dic(Cl.Value)(0).Offset(, -5).Interior.Color = vbYellow
            End If
            If Cl.Offset(, -4).Value <> Dic(Cl.Value)(2) Then
               Dic(Cl.Value)(0).Offset(, -4).Value = Cl.Offset(, -4).Value
               Dic(Cl.Value)(0).Offset(, -4).Interior.Color = vbYellow
            End If
         Else
            Cl.EntireRow.Copy Sheets("Data").Range("A" & UsdRws + 1)
            Sheets("Data").Range("A" & UsdRws + 1).Resize(, 17).Interior.Color = vbYellow
            UsdRws = UsdRws + 1
         End If
      Next Cl
   End With
End Sub

A million THANK YOU's

Fluff!​

That worked!!!!!

 

[Fluff]

You're welcome & thanks for the feedback.