stop auto updating date next day

[swapnilpradhan2688]

I want to stop auto-updating date the next day. I used today() function but it is not helping.

thank you

 

[arthurbr]

Perhaps try =TEXT(TODAY(),"dd/mm/yy")

 

[swapnilpradhan2688]

if i entered data todays date should be dislplayed.

roll no	name	date
1	xyz	28/06/2020
2	abc	28/06/2020

but when i enter data on 29/06/2020, date should not be dynamically update of 28/06/2020

roll no	name	date
1	xyz	28/06/2020
2	abc	28/06/2020
3	def	29/06/2020

it should be like this for next day without auto updating previous date

 

[Peter_SSs]

I want to stop auto-updating date the next day. I used today() function but it is not helping.

You can't do that with a formula.

You could use vba with this Worksheet_Change event code. Test in a copy of your workbook.
I have assumed that the entries are in columns A:B with date to go into column C.
To implement ..
1. Right click the sheet name tab and choose "View Code".
2. Copy and Paste the code below into the main right hand pane that opens at step 1.
3. Close the Visual Basic window & test.
4. Your workbook will need to be saved as a macro-enabled workbook (*.xlsm).

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, rw As Range
  Dim Date_Val As Variant
  
  Set Changed = Intersect(Target, Columns("A:B"), Rows("2:" & Rows.Count))
  If Not Changed Is Nothing Then
    Application.EnableEvents = False
      For Each rw In Changed.EntireRow.Resize(, 2).Rows
        If Len(rw.Cells(1).Value & rw.Cells(2).Value) > 0 Then
          Date_Val = Date
        Else
          Date_Val = ""
        End If
        Range("C" & rw.Row).Value = Date_Val
      Next rw
    Application.EnableEvents = True
  End If
End Sub