Stop macro from changing sheets.

[Livin404]

We have a recorded macro that works fine, basically one types their work number and it triggers a Vlookup and auto fills a disposition log with details like if they were to checkout a tool. We have the same function when a tool is returned. There are two things I'm looking for; the first one is when the macro is activated it switches sheets to the log. We don't want this to happen, we want to sheet to remain on the data entry sheet. If we can do that will we be able to hide the log (Sheet) or do we need another macro to do that?
Here is our macro.
Sub SIGNOUT1()
'
' SIGNOUT1 Macro
'
'
Range("C28:G28").Select
Selection.Copy
Sheets("Sign out ").Select
Range("A3").Select
Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
xlNone, SkipBlanks:=False, Transpose:=False
Rows("3:3").Select
Application.CutCopyMode = False
Selection.Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
End Sub

Sub SIGNIN1()
'
' SIGNIN1 Macro
'
'
Range("C28:G28").Select
Selection.Copy
Sheets("Sign in ").Select
Range("A3").Select
Selection.PasteSpecial Paste:=xlPasteValuesAndNumberFormats, Operation:= _
xlNone, SkipBlanks:=False, Transpose:=False
Rows("3:3").Select
Application.CutCopyMode = False
Selection.Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
End Sub

 

[JLGWhiz]

See how this works

Sub SIGNOUT1()
'
' SIGNOUT1 Macro
'
'
Range("C28:G28").Copy
With Sheets("Sign out ")
    .Range("A3").PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    Application.CutCopyMode = False
    .Rows("3:3").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
End With
End Sub

Sub SIGNIN1()
'
' SIGNIN1 Macro
'
'
Range("C28:G28").Copy
With Sheets("Sign in ")
    .Range("A3").PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    Application.CutCopyMode = False
    .Rows("3:3").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
End With
End Sub

 

[Livin404]

Thank you and it works, but the strangest thing happened the entry sheet shifts down a row, every time we select the sign-in or sign-out button. More good news is now we can at least hide the sheets.

 

[JLGWhiz]

You copied the code before I finished editing it.

With Sheets("Sign in ")
    .Range("A3").PasteSpecial Paste:=xlPasteValuesAndNumberFormats
    Application.CutCopyMode = False
    .Rows("3:3").Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
End With

Note that the line beginning with .Rows has a period in front of rows. That ties it to the sheet in the With statement. You need to add the period to that line in both the Sign in and Sign out codes. That will stop the row insert on the active sheets and put them on the correct sheets.

 

[Livin404]

Wow, strange one little period makes all the difference. It works perfectly now. Thank you so much!

 

[JLGWhiz]

Wow, strange one little period makes all the difference. It works perfectly now. Thank you so much!

Periods are important things.
Regards, JLG