Store a number on another sheet

[jcaptchaos2]

Hello,

I have a workbook where the employee types a number in cell "B16" the worksheet name is "Interface" they then press a macro button which prints out a label. I want to add to the front of that macro to first store that number in the first open cell of another worksheet lets say it's called "Dat". I would like it to be stored in column "B". What else that would be great is if it would check the list in column "B" and if the number is already there throw up a flag of some type.

 

[VoG]

Try

Sheets("Dat").Range("B" & Rows.Count).End(xlUp).Offset(1).Value = Sheets("Interface").Range("B16").Value
If WorksheetFunction.CountIf(Sheets("Dat").Columns("B"), Sheets("Interface").Range("B16").Value) > 1 Then MsgBox "Dup", vbInformation

 

[jcaptchaos2]

VoG,

Perfect, thanks for the ultra fast response.

 

[jcaptchaos2]

VoG,

If you don't mind I need a little more help on this, here is my full code and what I would like it to do is stop if that number is already in the list. I added the code you gave me but it still puts the number in column "B" on the "DAT" sheet, I don't need it to do that what I need is for it to stop there and then make the employee type in a different number.

Sub Packing()
'
' packing Macro
'

'
    Sheets("Dat").Range("B" & Rows.Count).End(xlUp).Offset(1).Value = Sheets("Interface").Range("B16").Value
If WorksheetFunction.CountIf(Sheets("Dat").Columns("B"), Sheets("Interface").Range("B16").Value) > 1 Then MsgBox "You have already used this number", vbInformation

    Range("B2").Select
    Sheets("Packing Slip Label").Select
    ActiveSheet.Unprotect
    ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True, _
        IgnorePrintAreas:=False
     ActiveSheet.Protect
    Sheets("Interface").Select
    Range("B2").Select
End Sub

 

[VoG]

Maybe like this

Sub Packing()
'
' packing Macro
'

'
Sheets("Dat").Range("B" & Rows.Count).End(xlUp).Offset(1).Value = Sheets("Interface").Range("B16").Value
If WorksheetFunction.CountIf(Sheets("Dat").Columns("B"), Sheets("Interface").Range("B16").Value) > 1 Then
    MsgBox "You have already used this number" & vbNewLine & "Please enter a unique number", vbInformation
    Sheets("Dat").Range("B" & Rows.Count).End(xlUp).ClearContents
    Exit Sub
End If
Sheets("Packing Slip Label").PrintOut
Range("B2").Select
End Sub

 

[jcaptchaos2]

Exactly what I needed, thank you so much for the quick response.