Streak W or L

[Stephen_IV]

Is there an easier way to do this, if anyone has some ideas, I would like to do this with out helper columns. I would not mind using VBA if needed. I am trying to get the streak in column D. Thanks in advance.

Streak Plus Minus.xlsm A B C D 1 W/L Win Loss Streak 2 3 L 1 1 - 4 W 2 0 ++ 5 L 0 1 - 6 W 1 0 + 7 W 2 0 ++ 8 L 0 1 - 9 L 0 2 -- 10 L 0 3 --- 11 W 1 0 + 12 W 2 0 ++ 13 L 0 1 - 14 L 0 2 -- 15 L 0 3 --- 16 L 0 4 ---- 17 L 0 5 ----- 18 W 1 0 + 19 L 0 1 - 20 W 1 0 + Sheet1 Cell Formulas Range Formula B3 B3 =--(B2+OR(AND(A3<>"W",A2<>"W"),A3<>"W"))*(A3<>"W") C3:C20 C3 =--(C2+OR(AND(A3<>"W",A2<>"W"),A3<>"W"))*(A3<>"W") D3:D20 D3 =IF(A3="W",REPT("+",--(B2+OR(AND(A3<>"L",A2<>"L"),A3<>"L"))*(A3<>"L")),REPT("-",--(C2+OR(AND(A3<>"W",A2<>"W"),A3<>"W"))*(A3<>"W"))) B4:B20 B4 =--(B3+OR(AND(A4<>"L",A3<>"L"),A4<>"L"))*(A4<>"L")

 

[Toadstool]

Hi STPHEN_IV,

Does this work for you?

STEPHEN_IV2.xlsx
	A	B	C	D
1	W/L	Win	Loss	Streak
2
3	L	1	1	-
4	W	2	0	++
5	L	0	1	-
6	W	1	0	+
7	W	2	0	++
8	L	0	1	-
9	L	0	2	--
10	L	0	3	---
11	W	1	0	+
12	W	2	0	++
13	L	0	1	-
14	L	0	2	--
15	L	0	3	---
16	L	0	4	----
17	L	0	5	-----
18	W	1	0	+
19	L	0	1	-
20	W	1	0	+
Sheet1

Cell Formulas
Range	Formula
B3	B3	=--(B2+OR(AND(A3<>"W",A2<>"W"),A3<>"W"))*(A3<>"W")
C3:C20	C3	=--(C2+OR(AND(A3<>"W",A2<>"W"),A3<>"W"))*(A3<>"W")
D3:D20	D3	=CHOOSE(MIN(MAX(C3-B3,-1),1)+2,REPT("+",B3),"-",REPT("-",C3))
B4:B20	B4	=--(B3+OR(AND(A4<>"L",A3<>"L"),A4<>"L"))*(A4<>"L")

 

[Habtest]

Shouldn't row 3 be "L, 0, 1, -", or am I missing something? See if this works:

Book1
	A	B	C	D
1	W/L	Win	Loss	Streak
2
3	L	0	1	-
4	W	1	0	+
5	L	0	1	-
6	W	1	0	+
7	W	2	0	++
8	L	0	1	-
9	L	0	2	--
10	L	0	3	---
11	W	1	0	+
12	W	2	0	++
13	L	0	1	-
14	L	0	2	--
15	L	0	3	---
16	L	0	4	----
17	L	0	5	-----
18	W	1	0	+
19	L	0	1	-
20	W	1	0	+
Sheet1

Cell Formulas
Range	Formula
B3:C20	B3	=IF($A2<>$A3,--($A3=LEFT(B$1,1)),(B2+1)*(B2<>0))
D3:D20	D3	=REPT(IF(B3=0,"-","+"),SUM(B3:C3))

 

[Peter_SSs]

would like to do this with out helper columns. ... I am trying to get the streak in column D.

Like this? (I am also assuming you have something wrong at the top of your results columns)

21 09 17.xlsm
	A	B	C	D
1	W/L			Streak
2
3	L			-
4	W			+
5	L			-
6	W			+
7	W			++
8	L			-
9	L			--
10	L			---
11	W			+
12	W			++
13	L			-
14	L			--
15	L			---
16	L			----
17	L			-----
18	W			+
19	L			-
20	W			+
Streaks

Cell Formulas
Range	Formula
D3:D20	D3	=IF(A3=A2,D2&LEFT(D2,1),IF(A3="L","-","+"))

 

[Stephen_IV]

Thanks everyone for your help and for looking into this post. Peter_SSs that is exactly what I needed!!! I appreciate your help and guidance!

 

[Peter_SSs]

You're welcome. Glad we could help. Thanks for the follow-up.