SUMIFS formula by date range with multiple conditions

[Parebody]

Looking for some assistance. I want to update my formula to extract data between the date range in cell B12 & B13, instead of just data from the start date in B12. How would I update the formula to recognize the date range?


=SUM(IF(('[Production Recap 2020.xlsm]Data'!$A$2:$A$9998=$B$12)*('[Production Recap 2020.xlsm]Data'!$B$2:$B$9998=$B$14)*('[Production Recap 2020.xlsm]Data'!$C$2:$C$9998=A16),'[Production Recap 2020.xlsm]Data'!$F$2:$F$9998))

 

[Dave Patton]

Sample data posted with XL2BB would have been very helpful.
Click on the icon below the f(x) and paste to a clean sheet.
Review the logic and the formula and then adapt to your data.

T202010b.xlsm
	A	B	C	D	E	F
1	Start	20-10-20				3000
2	End	21-10-20
3
4		B_Col	C_Col			F_Col
5	Criteria	A	123
6	Dates
7	01-10-20	A	123			1200
8	20-10-20	A	123			1400
9	20-10-20	B	123			1500
10	21-10-20	A	123			1600
11	31-10-20	A	123			1700
12
3b

Cell Formulas
Range	Formula
F1	F1	=SUMPRODUCT(--(A7:A11>=B1),--(A7:A11<=B2),--(B7:B11=B5),--(C7:C11=C5),F7:F11)

 

[Dave Patton]

I didn't include the Sumifs; see below.

T202010b.xlsm
	A	B	C	D	E	F
1	Start	20-10-20				3000
2	End	21-10-20				3000
3
4		B_Col	C_Col			F_Col
5	Criteria	A	123
6	Dates
7	01-10-20	A	123			1200
8	20-10-20	A	123			1400
9	20-10-20	B	123			1500
10	21-10-20	A	123			1600
11	31-10-20	A	123			1700
12
3b

Cell Formulas
Range	Formula
F1	F1	=SUMPRODUCT(--(A7:A11>=B1),--(A7:A11<=B2),--(B7:B11=B5),--(C7:C11=C5),F7:F11)
F2	F2	=SUMIFS(F7:F11,A7:A11,">="&B1,A7:A11,"<="&B2,B7:B11,B5,C7:C11,C5)

 

[Parebody]

Mr. Patton, that worked perfectly. Thank you very much for your help!

 

[Dave Patton]

Thanks for the feedback.