Take screenshot and paste to Powerpoint slide

[johnsonk]

Hi, I am trying to take a screenshot of my userform and paste it onto a powerpoint file slide, I need it delete what is on the slide and replace with the new screenshot, I have managed to get it to take a screenshot but that's about it the rest I can not figure out, can anyone help.

This is what I have at the moment.

Dim MyPPT As Object
Set MyPPT = CreateObject("Powerpoint.application")
MyPPT.Visible = True
MyPPT.Presentations.Open "P:\MyFile.pptm"
Application.SendKeys "(%{1068})"
DoEvents

Regards

 

[Domenic]

Since you haven't provided all of the relevant information, I have made the following assumptions...

1) The screenshot to be deleted and replaced is located on the first slide of the presentation.

2) The screenshot to be replaced is the last shape in the ZOrder for the slide.

If you need to specify a different slide and/or shape, you'll need to amend the code accordingly. Post back if you need help in making any changes.

Private Sub CommandButton1_Click()

    Application.SendKeys "(%{1068})", True
  
    DoEvents
  
    Dim MyPPT As Object
    Set MyPPT = CreateObject("Powerpoint.Application")
  
    MyPPT.Visible = True
  
    Dim MyPres As Object
    Set MyPres = MyPPT.Presentations.Open("P:\MyFile.pptm")
  
    Dim leftPos As Single
    leftPos = 10 'default left position in case a shape doesn't already exist
  
    Dim topPos As Single
    topPos = 10 'default top position in case a shape doesn't already exist
  
    With MyPres.slides(1).Shapes 'first slide
        If .Count > 0 Then 'check whether there's at least one shape
            With .Item(.Count) 'last shape in zorder
                leftPos = .Left 'remember left position
                topPos = .Top 'remember top position
                .Delete 'delete shape
            End With
        End If
        .Paste 'paste screenshot
        With .Item(.Count) 'last shape in zorder
            .Left = leftPos 'set left position
            .Top = topPos 'set top position
        End With
    End With
      
End Sub

Hope this helps!

 

[johnsonk]

Domenic, That works perfect, is there a way to do the same but to an open powerpoint file so when the powerpoint file is refreshed it will update.

Regards

 

[Domenic]

To refer to a specific presentation...

    Set MyPres = MyPPT.Presentations("Presentation1.pptm")

To refer to the active presentation...

    Set MyPres = MyPPT.ActivePresentation

 

[johnsonk]

Sorry for the late reply Domenic, that worked perfect thank you.

 

[Domenic]

You're very welcome, I'm glad I could help.

Cheers!