text bullets and numbering

[Forestq]

Hi,

I have added Textbox into PPT and I want to put there a text with few line - each should be marked by bullet (dot or circle) or by number (like 1, 2).
Example:

1. Some long text
2. Other text etc....

How can I do it?

activeSlide.Shapes.AddTextbox msoTextOrientationHorizontal, Left:=0, Top:=60, Width:=500, Height:=50
With activeSlide.Shapes(1).TextFrame
    .TextRange.Text = ""
    .TextRange.Font.Color = RGB(0, 32, 96)
    .TextRange.Font.Size = 12
    .TextRange.Font.Name = "Arial (Body)"
    .WordWrap = msoCTrue
    .TextRange.Font.Underline = msoTrue
End With

 

[pbornemeier]

Try bit at bottom of this code:

Sub PlayWithTextBox()

    ActiveWindow.Selection.SlideRange.Shapes.AddTextbox(msoTextOrientationHorizontal, Left:=0, Top:=60, Width:=500, Height:=50).Select
    With ActiveWindow.Selection.SlideRange.Shapes(1)
        With .TextFrame.TextRange.Font
            .Name = "Arial"
            .Size = 12
            .Italic = True
            .Bold = True
            .Shadow = True
            .Color = rgbGreen
            .Underline = True
        End With
        .TextFrame.VerticalAnchor = msoAnchorMiddle
        .TextFrame.HorizontalAnchor = msoAnchorCenter
        .TextFrame.TextRange.Paragraphs.ParagraphFormat.Alignment = ppAlignLeft

        .Fill.ForeColor.RGB = rgbLightBlue
        .Fill.Transparency = 0
        
        .Line.DashStyle = 1
        .Line.Style = 1
        .Line.ForeColor.RGB = rgbRed
        .Line.Weight = 1
        .TextFrame.TextRange.Text = "First Line" & vbLf & "Second Line" & vbLf & "Third Line"
        
        With .TextFrame.TextRange.ParagraphFormat.Bullet
            .Visible = True
            .RelativeSize = 1.25
            With .Font
                .Color = RGB(255, 0, 255)
                .Name = "Symbol"
            End With
            .Character = 183
        End With
        
    End With


End Sub