Time stamp when multiple cells are modified

[sergiumirze]

Hello All,

I have a file for entering products in a warehouse, so when the product entered the WH its making an automatic timestamp ( the code below).
Now I created another column for when the product was removed form warehouse and i need a time stamp in column 7 when in column 6 was selected the specific text "Removed" .

Can u please help me ?


Private Sub Worksheet_Change(ByVal Target As Range)
For Each cell In Target.Cells
If cell.Row > 1 And cell.Column = 1 Then
If cell.Offset(0, 2).Value = "" Then
cell.Offset(0, 2).Value = Now()
End If

End If
Next
End Sub

 

[DanteAmor]

Try this:

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim cell As Range, rng As Range
  Set rng = Intersect(Target, Range("A2:A" & Rows.Count & ",F2:F" & Rows.Count))
  If Not rng Is Nothing Then
    Application.EnableEvents = False
    For Each cell In rng
      If cell.Column = 1 And cell.Offset(0, 2).Value = "" Then
        cell.Offset(0, 2).Value = Now()
      ElseIf Cells(cell.Row, 1) <> "" And Cells(cell.Row, 6) = "Removed" Then
        Cells(cell.Row, 7) = Now()
      End If
    Next
    Application.EnableEvents = True
  End If
End Sub