Two codes - Private Sub Worksheet_Change(ByVal Target As Range)

[jdmchic00]

Hi!
I have a question. How can I get two codes to run on the same sheet????


Private Sub Worksheet_Change(ByVal Target As Range)
ActiveSheet.Activate
If Not Application.Intersect(Range("B4"), Range(Target.Address)) Is Nothing Then
Select Case Target.Value
Case Is = "All": Rows("14:22").EntireRow.Hidden = True
Rows("8:13").EntireRow.Hidden = False
Case Is = "Kelsey Lopez": Rows("14:22").EntireRow.Hidden = False
Rows("8:13").EntireRow.Hidden = True
End Select

Private Sub Worksheet_Change(ByVal Target As Range)
ActiveSheet.Activate
If Not Application.Intersect(Range("B52"), Range(Target.Address)) Is Nothing Then
Select Case Target.Value
Case Is = "Advanced Stage": Rows("60:62").EntireRow.Hidden = False
Rows("58:59").EntireRow.Hidden = True
Case Is = "Early Stage": Rows("58:59").EntireRow.Hidden = False
Rows("60:62").EntireRow.Hidden = True
Case Is = "Total Open Pipeline": Rows("58:62").EntireRow.Hidden = False

End Select
End If
End Sub



Thanks!

 

[Fluff]

Hi & welcome to MrExcel.
How about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Not Application.Intersect(Range("B4"), Target) Is Nothing Then
      Select Case Target.Value
         Case "All"
            Rows("14:22").EntireRow.Hidden = True
            Rows("8:13").EntireRow.Hidden = False
         Case "Kelsey Lopez"
            Rows("14:22").EntireRow.Hidden = False
            Rows("8:13").EntireRow.Hidden = True
      End Select
   ElseIf Not Application.Intersect(Range("B52"), Target) Is Nothing Then
      Select Case Target.Value
         Case "Advanced Stage"
            Rows("60:62").EntireRow.Hidden = False
            Rows("58:59").EntireRow.Hidden = True
         Case "Early Stage"
            Rows("58:59").EntireRow.Hidden = False
            Rows("60:62").EntireRow.Hidden = True
         Case "Total Open Pipeline"
            Rows("58:62").EntireRow.Hidden = False
      End Select
   End If
End Sub

 

[jdmchic00]

Thank you for your quick help!!

 

[Fluff]

You're welcome.