unique entry lookup in large table

[luke w]

Hello Excel Gurus

Well i've pulled enough hair that i thought I should ask the experts.

I have a large table of employee names, approximately 1000. We have a phone operator that actually scrolls through this list to find the name of the person they are looking for...can you say boring?

Anyway, what I would like to do is put something together that allows them to enter the first name of the person in a cell and have it return all of the unique entries with that name, which of course would include their extension number in a new table.

Vlookup won't work, and i'm trying an Offset Match in the following format, but am stuck because it will only return one entry as well.

=OFFSET('Formatted Data'!$A$1,MATCH($B$1,'Formatted Data'!$A$2:$A$1000,0),1)

 

[Aladin Akyurek]

Wouldn't AutoFilter do the job? If not, care to provide a small sample? Also, are you on Excel 2003?

 

[pgc01]

Hi Luke

Here is one solution.

This solution accepts an input string that does not have to be the first name, any part of the name will do (I think it is more flexible).

In the example I post, the operador typed rob and 2 names were found

John ROBbins
ROBin Ford

In E3

=IF(SUM(--ISNUMBER(SEARCH($E$1,$A$2:$A$1000)))<=ROW()-ROW($E$3),"",INDEX($A:$A,SMALL(IF(ISNUMBER(SEARCH($E$1,$A$2:$A$1000)),ROW($A$2:$A$1000),1000000),ROW()-ROW($E$3)+1)))

This is an array formula and so MUST be entered with CTRL+SHIFT+ENTER and not just ENTER.

In F3

=IF(SUM(--ISNUMBER(SEARCH($E$1,$A$2:$A$1000)))<=ROW()-ROW($E$3),"",INDEX($B:$B,SMALL(IF(ISNUMBER(SEARCH($E$1,$A$2:$A$1000)),ROW($A$2:$A$1000),1000000),ROW()-ROW($E$3)+1)))

This is an array formula and so MUST be entered with CTRL+SHIFT+ENTER and not just ENTER.

Copy down 10 rows, to get the first 10 matches.

Hope this helps
PGC

Book1.xls
	A	B	C	D	E	F	G	H
1	Names	Tel		Name	rob
2	JohnSmith	1234
3	MaryRiley	5678		Matches	JohnRobbins	0912
4	JohnRobbins	0912			RobinFord	8858
5	KarenGrey	2258
6	JohnClark	3365
7	RobinFord	8858
8
9
10
Sheet3

 

[Aladin Akyurek]

Book3
	A	B	C	D	E	F	G	H
1	First Name	Last Name	Extension		First	John
2	John	Smith	1234		Last
3	Mary	Riley	5678		Count	3
4	John	Robbins	912			First Name	Last Name	Extension
5	Karen	Grey	2258		1	John	Smith	1234
6	John	Clark	3365		3	John	Robbins	912
7	Robin	Ford	8858		5	John	Clark	3365
8
9
Sheet1

F1:F2 is for user entered-value(s). It can consist of either just a first name or a last name or both.

F3:

=SUMPRODUCT(ISNUMBER(SEARCH(F1&"#"&F2,$A$2:$A$7&"#"&$B$2:$B$7))+0)

E5:

=IF(ROWS($E$5:E5)<=$F$3,SMALL(IF(ISNUMBER(SEARCH($F$1&"#"&$F$2,$A$2:$A$7&"#"&$B$2:$B$7)),ROW($A$2:$A$7)-ROW($A$2)+1),ROWS($E$5:E5)),"")

which is confirmed with control+shift+enter (not just with enter) then copied down.

F5, copied across and down:

=IF(N($E5),INDEX(A$2:A$7,$E5),"")

 

[luke w]

Thanks PGC01!

this works great!!

 

[luke w]

sorry spoke too soon. i'm getting a "#REF!" in the cells that don't have matches for the names. i don't know if the name i enter will return with 5 10 15 etc. names with the same match.

i've tried conditional formatting but for some reason its not working. any other suggestions...perhaps an addition to the code?